SICP递归let定义

Question

对于

(let ((fact 
        (lambda (n)
            (if (= n 1)
                1
                (* n (fact (- n 1)))))))
(fact 10))

方案出错，我想确认我的推理是否正确，

因为(let ((var1 arg1)) body) 相当于在var1 绑定到arg1 的环境中评估身体。

上面，当我们试图在绑定调用之前计算arg1 时，我们没有找到引用，因为这正是我们试图绑定它以使其可用

但是为什么这不抛出

(let ((fact (lambda (n) 
             (if (= n 1) 1 (* n (fact (- n 1))))))) 
  (display 10))

因为我们也在尝试在那里进行绑定。

还有为什么这个不抛出

(define factorial
    (lambda (n)
      (if (= n 0)
          1
          (* n (factorial (- n 1))))))
          
(factorial 10)

Answer 1

原因是“variable fact is not bound”错误只有在我们实际尝试查找“fact”的值时才会出现。考虑

(let ((fact (lambda (n) (if (= n 0)
                            1
                            (* n (fact (- n 1)))))))
 (fact 0))

这不会导致错误，因为我们没有输入else 子句，因此不会尝试使用未绑定变量fact 的值。然而，用1 尝试同样的事情确实会给我们带来错误。

我们在使用define 时不会遇到错误，因为define 和let 有不同的规则。在let 绑定中，您创建了一个新的词法范围，并且fact 在let 绑定中的绑定不会从let“泄漏”到外部世界。由于 let 赋值的右侧只能引用来自外部世界的绑定，所以右侧不能引用绑定 fact。

然而，在define 语句中，重点是在当前作用域中引入一个新的绑定（而不是创建一个新作用域）。在define 绑定中，赋值的右侧必须只引用来自外部世界的变量——但这可能包括变量defined，只要访问它隐藏在lambda 后面并因此完成偷懒。

事实上，考虑以下几点：

(define is-even
  (lambda (n) (or (= n 0)
                  (is-odd (- n 1)))))

(define is-odd
  (lambda (n) (and (not (= n 0))
                   (is-even (- n 1)))))

(display (is-odd 55))

在这种情况下，当我们实际调用is-even 时，is-odd 是defined，与is-even 在同一范围内，因此我们可以查找它的值。同样，当我们调用is-odd 时，is-even 已经定义好了，因此我们对其值进行了绑定。

请注意，以下操作不起作用：

(define is-even
  (lambda (n) (or (= n 0)
                  (is-odd (- n 1)))))

(display (let ((is-odd (lambda (n) (and (not (= n 0))
                                        (is-even (- n 1))))))
            (is-odd 55)))

这是因为这里的is-odd 绑定不与is-even 在同一范围内。它在比is-even 更本地的绑定中定义。在is-even 定义中引用的is-odd 不能与在let 语句中创建的is-odd 相同，因为这个is-odd 是一个本地绑定，因此不能在@ 更广泛的范围内引用987654354@ 中定义。

如果我们使用“动态范围”的老式 LISP 概念，也称为“按名称调用语义”，则后一个示例将非常有效。但是，Scheme 不支持动态范围（在我看来这绝对是最好的）。