Clojure：原子和参考的惯用用法？

Question

我正在编写一些 Clojure 代码，该代码将引用映射并增加映射中的键值对。我认为我正确使用了 ref，但我不确定 atom。我需要使用swap吗！更地道？我是 STM 和 Clojure 的新手，这看起来线程安全/理智吗？我错过了什么？

(defn increment-key [ref key]
    (dosync
        (if (= (get @ref key) nil)
            (alter ref assoc key (atom 1))
            (alter ref assoc key (atom (inc @(get @ref key)))))))

(defn -main [& args]
    (def my-map (ref {}))
    (increment-key my-map "yellow")
    (println my-map)
    (increment-key my-map "yellow")
    (println my-map))

打印

$ lein run
#<Ref@494eaec9: {yellow #<Atom@191410e5: 1>}>
#<Ref@494eaec9: {yellow #<Atom@7461373f: 2>}>

Answer 1

这样做不太符合 Clojure 的习惯：在持久数据结构中嵌入可变对象通常会破坏不可变数据结构的全部意义。

我会完全避免使用内部原子，只需要一个与键关联的数字。那么my-map中包含的整个数据结构将是不可变的。

至于线程安全：这实际上取决于您将如何使用它。在这种情况下，ref 似乎有点矫枉过正，因为只有当您需要跨多个 ref 协调事务时才真正需要它，而您在这里没有。可能atom 足以满足您的要求。

以下是您可以解决的方法：

(defn increment-key [ref key]
  (swap! ref update-in [key] (fn [n] (if n (inc n) 1))))

(def my-map (atom {}))
(increment-key my-map "yellow")
(println my-map)  ;; => {"yellow" 1}
(increment-key my-map "yellow")
(println my-map)  ;; => {"yellow" 2}

编辑：更好的做法是将可变性排除在您的函数之外，并将 increment-key 定义为纯函数。

(defn increment-key [m key]
  (assoc m key (if-let [n (m key)] (inc n) 1)))

(def my-map (atom {}))
(swap! my-map increment-key "yellow")
(println my-map)   ;; => {"yellow" 1}
(swap! my-map increment-key "yellow")
(println my-map)   ;; => {"yellow" 2}