在Fortran中传递带有参数的外部函数[重复]

Question

我最小的、可重现的示例如下所示：在我的程序mymain 中，我调用了一个子程序，该子程序有一个外部函数f1 和一个变量result 作为参数。在子例程中，函数完成了一些事情（对于这个例子，它只是在特定点被评估），结果通过参数result返回。

PROGRAM mymain

    IMPLICIT NONE

    REAL(KIND=8)    f1
    REAL(KIND=8)    result

    EXTERNAL f1


    CALL sub1(f1,result)

    PRINT *,result

END PROGRAM mymain

SUBROUTINE sub1(f1,result)

    IMPLICIT NONE

    REAL(KIND=8)                ::f1
    REAL(KIND=8), INTENT(OUT)   ::result
    REAL(KIND=8)                ::input

    EXTERNAL f1

    input=0.5

    result=f1(input)

END SUBROUTINE sub1

REAL(KIND=8) FUNCTION f1(x)

    REAL(KIND=8), INTENT(IN)    ::x
    REAL(KIND=8)                ::const

    const=1.

    f1=x**2+const

END FUNCTION f1

我的问题是我想从mymain 中更改函数f1 中的变量const。

在我的实际问题中，子例程是 Fortran 库之一，它采用外部函数的积分，我需要多次调用此子例程，但始终在外部函数中使用不同的参数。

我不知道该怎么做，因为我不能像这样从mymain 调用子例程

CALL sub1(f1(x,const),result)

Answer 1

有几种方法可以实现您想要的，但我建议您学习使用 Fortran 的模块功能。这将允许您封装函数的信息。下面，我介绍两个模块。第一个用于为real 类型的 kind 类型参数设置一个命名常量。在您的代码中，当您使用 real(kind=8) 时，您使用的是编译器特定的值。第二个定义函数f(x)和设置const的方法

!
! Set kind type parameter for double precision
!
module mytype
  implicit none
  integer, parameter :: dknd = kind(1.d0)
end module mytype
!
! Module defining the function
!
module fcn
 use mytype
 implicit none
 private                  ! Make everything private
 public f, set_const      ! Only allow access to f() and set_const().
 real(dknd) :: const = 0  ! Default constant value
 contains
   !
   ! Subroutine to set const.  Can be generalized to multiple constants.
   ! Call this prior to invoking f(x).
   !
   subroutine set_const(val)
     real(dknd), intent(in) :: val
     const = val
   end subroutine
   !
   ! Obviously, the function f(x)
   !
   function f(x)
     real(dknd) f
     real(dknd), intent(in) :: x
     f = x**2 + const
   end function f 
end module fcn

program mymain
  use fcn                  ! Use fcn to get access f and set_const
  use mytype               ! Use mytype to get access to dknd
  implicit none
  real(dknd) result

  call set_const(1._dknd)  ! Set const = 1
  call sub1(f, result)
  print *, result

  call set_const(2._dknd)  ! Set const = 2
  call sub1(f, result)
  print *, result
end program mymain
!
! Your subroutine.  DO NOT "USE FCN", here!
!
subroutine sub1(f1, result)
  use mytype                 ! Use mytype to get access to dknd
  implicit none
  real(dknd), external :: f1 ! f1 is external real(dknd) function
  real(dknd), intent(out) :: result
  real(dknd) input
  input = 0.5_dknd
  result = f1(input)
end subroutine sub1