将递归过程转换为迭代过程 - SICP 练习 1.16

Question

在计算机程序的结构和解释一书中，有一个使用连续平方计算指数的递归过程。

(define (fast-expt b n)
    (cond ((= n 0) 
        1)
    ((even? n) 
        (square (fast-expt b (/ n 2))))
   (else 
        (* b (fast-expt b (- n 1))))))

现在在练习 1.16：

练习 1.16：设计一个迭代求幂过程的过程，该过程使用连续平方并使用对数步数， 和`fast-expt`一样。 （提示：使用观察

(b(^n/2))^2 = (b(^2))^n/2

，与指数n 和基数b 一起保留一个附加状态变量a，并以乘积ab^n 在不同状态之间保持不变的方式定义状态转换。进程开始时a 取为1，由进程结束时a 的值给出答案。一般来说，定义一个在状态之间保持不变的不变量的技术是思考迭代算法设计的一种强有力的方法。）

我花了一个星期，我完全不知道如何做这个迭代过程，所以我放弃并寻找解决方案。我找到的所有解决方案都是这样的：

(define (fast-expt a b n)
    (cond ((= n 0) 
        a)
    ((even? n) 
        (fast-expt a (square b) (/ n 2)))
   (else 
        (fast-expt (* a b) b (- n 1)))))

现在我明白了

        (fast-expt a (square b) (/ n 2)))

使用书中的提示，但是当n 很奇怪时，我的大脑爆炸了。在递归过程中，我明白了原因

        (* b (fast-expt b (- n 1))))))

有效。但是在迭代过程中，就变得完全不同了，

        (fast-expt (* a b) b (- n 1)))))

它工作得很好，但我绝对不明白如何自己达到这个解决方案。看起来非常聪明。

有人可以解释为什么迭代解决方案是这样的吗？解决这类问题的一般思路是什么？

2021 年更新： 去年，我完全忘记了这个练习和我看到的解决方案。我尝试解决它，最后我使用练习中提供的不变量作为转换状态变量的基础自己解决了它。我使用现在接受的答案来验证我的解决方案。谢谢@Óscar López。

Answer 1

为了让事情更清晰，这里有一个稍微不同的实现，请注意我使用了一个名为 loop 的辅助过程来保留原始过程的数量：

(define (fast-expt b n)
  (define (loop b n acc)
    (cond ((zero? n) acc)
          ((even? n) (loop (* b b) (/ n 2) acc))
          (else (loop b (- n 1) (* b acc)))))
  (loop b n 1))

这里的acc 是什么？它是一个参数，用作结果的累加器（在书中他们将此参数命名为a，恕我直言acc 是一个更具描述性的名称）。因此，一开始我们将acc 设置为适当的值，然后在每次迭代中更新累加器，保留不变量。

一般来说，这是理解算法的迭代、尾递归实现的“技巧”：我们将一个额外的参数与我们目前计算的结果一起传递，并在我们到达时返回它递归的基本情况。顺便说一句，如上所示的迭代过程的通常实现是使用命名let，这是完全等效的，并且写起来更简单：

(define (fast-expt b n)
  (let loop ((b b) (n n) (acc 1))
    (cond ((zero? n) acc)
          ((even? n) (loop (* b b) (/ n 2) acc))
          (else (loop b (- n 1) (* b acc))))))