Python 迭代器的 Perl 版本是什么？

Question

我在工作中学习 Perl，并乐在其中。我通常用 Python 做我的工作，但老板想要 Perl。

Python 和 Perl 中的大多数概念都很好地匹配：Python dictionary=Perl hash; Python 元组=Perl 列表； Python 列表=Perl 数组；等等。

问题：有没有Iterator/Generator 的 Python 形式的 Perl 版本？

一个例子：生成斐波那契数的经典 Python 方法是：

#!/usr/bin/python

def fibonacci(mag):
     a, b = 0, 1
     while a<=10**mag:
         yield a
         a, b = b, a+b

for number in fibonacci(15):  
     print "%17d" % number

如果您想根据需要生成更大列表的子部分，迭代器也很有用。 Perl 的“列表”看起来更静态——更像是一个 Python 元组。在 Perl 中，foreach 可以是动态的还是仅基于静态列表？

Iterator 的 Python 形式是我已经习惯的一种形式，我没有发现它在 Perl 中记录... ex) 在 Perl 中编写斐波那契子程序？是否有我缺少的 Perl yield？

具体来说——我该怎么写：

#!/usr/bin/perl
use warnings; use strict; # yes -- i use those!

sub fibonacci {
   # What goes here other than returning an array or list? 
}

foreach my $number (fibonacci(15)) { print $number . "\n"; }

在此先感谢您对新手的善意...

Answer 1

迭代器的概念在 Perl 中略有不同。您基本上希望在持久变量上返回一个“关闭”的一次性子例程。

use bigint;
use strict;
use warnings;

sub fibonacci {
    my $limit = 10**( shift || 0 );
    my ( $a, $b ) = ( 0, 1 );
    return sub { 
        return if $a > $limit;
        ( my $r, $a, $b ) = ( $a, $b, $a + $b );
        return $r;
    };
}
my $fit = fibonacci( 15 );
my $n = 0;
while ( defined( my $f = $fit->())) { 
     print "F($n): $f\n";
     $n++;
}

如果您不喜欢 while 循环，那么这里有两个关于一些语法糖的镜头，它们基本上完成了每个项目的循环。：

sub iterate ($$) {
    my $iter   = shift;
    my $action = shift;
    while ( defined( my $nextval = $iter->())) { 
        local *_ = \$nextval;
        $action->( $_ );
    }
    return;
}

iterate fibonacci( 15 ) => sub { print "$_\n"; };

sub iter (&$) { 
    my $action = shift;
    my $iter   = shift;
    while ( defined( my $nextval = $iter->())) { 
        local *_ = \$nextval;
        $action->( $_ );
    }
    return;
}

iter { print "$_\n" } fibonacci( 15 );

Answer 2

为了比 Python 的生成器更灵活的解决方案，我在 CPAN 上编写了模块 List::Gen，它提供了随机访问惰性生成器数组：

use List::Gen;

my $fib; $fib = cache gen {$_ < 2  ? $_ : $$fib[$_ - 1] + $$fib[$_ - 2]};

say "@$fib[0 .. 15]";  #  0 1 1 2 3 5 8 13 21 34 55 89 144 233 377 610

由于生成器伪装成数组，它们可以与普通的 perl 代码无缝混合。还有一种面向对象的方法：

my $fib; $fib = cache gen {$_ < 2 ? $_ : $fib->get($_ - 1) + $fib->get($_ - 2)};

say join ' ' => $fib->slice(0 .. 15);

在每种情况下，生成器都是惰性的，在创建时不计算任何内容，然后只计算满足切片所需的值。斐波那契数列的递归定义多次调用自身，因此使用cache 函数来确保每个值只计算一次。

您也可以将生成器用作迭代器：

while (my $num = $fib->next) {
    last if $num > 10**15;
    print "$_\n";
}

$fib->next也可以写成$fib->()。由于生成器还是随机访问的，可以$fib->reset()或者$fib->index = 10;

如果您有任何问题，请告诉我。

更新：

我发布了该模块的新版本 (0.80)，它可以更轻松地在生成器中使用迭代算法。这是一个与 OP 的示例非常相似的示例：

use List::Gen '*';

sub fibonacci {
    my $limit   = 10**shift;
    my ($x, $y) = (0, 1);

    While {$_ < $limit} gather {
        ($x, $y) = ($y, take($x) + $y)
    }
}

say for @{fibonacci 15};

如果你use bigint;在子之前或顶部，你当然可以：

say for @{fibonacci 400}; # or more

Answer 3

优秀的Higher-Order Perl 书（可在指定链接免费获得）包含大量相关主题的信息，特别是有一整章关于迭代器。作者通过“高阶”暗示使用 Perl 的能力作为具有一流函数的函数式语言来实现各种很酷的东西。这确实是一本非常好的书——我读了大部分内容，关于迭代器和流的章节非常棒。如果您打算编写 Perl 代码，我强烈建议您至少略读一遍。

Answer 4

有一种类似的方法可以生成迭代器/生成器，但它不像 Python 上那样是“一等公民”。

在 Perl 中，如果您没有看到您想要的（在 MANDATORY 访问CPAN FIRST！之后），您可以自己滚动类似于基于 Perl 闭包和匿名子例程的 Python 迭代器。

考虑：

use strict; use warnings;

sub fibo {
    my ($an, $bn)=(1,0);
    my $mag=(shift || 1);
    my $limit=10**$mag;
    my $i=0;

    return sub {
        ($an, $bn)=($bn, $an+$bn);      
        return undef if ($an >=$limit || wantarray );
        return $an;
    }
}

my $num;
my $iter=fibo(15);
while (defined($num=$iter->()) ) { printf "%17d\n", $num; }

子 fibo 维护一个 Perl closure，它允许维护持久变量。你可以通过一个类似于 C/C++ 的模块来做同样的事情。在fibo 内部，一个匿名子例程负责返回下一个数据项。

引用Perl Bible“在了解标量和列表上下文之间的区别之前你会很痛苦”——第 69 页（顺便说一句强烈推荐的书...）

在这种情况下，annon sub 只返回一个值。我所知道的在 Perl 中可以在标量上下文中工作的唯一循环机制是 while；我认为其他人在继续之前尝试填写列表。因此，如果您在列表上下文中调用 anon sub，它将忠实地返回下一个斐波那契数，这与 Python 的 for 迭代器不同，并且循环将终止。这就是我放置return undef if .... wantarray 的原因，因为它在所写的列表上下文中不起作用。

有办法解决这个问题。实际上，您可以编写像 map foreach 等一样的子例程，但它不像 Python 的 yield 那样简单。您将需要在 foreach 循环中使用一个附加函数。权衡是 Perl 方法具有巨大的功能和灵活性。

您可以在 Mark Jason Dominus 的优秀著作“Higher Order Perl”Chapter 4 is all about Interatorsbrian d foy 中阅读有关 Perl 迭代器的更多信息，在 Perl 评论中的 Interators 上也有出色的 article。

Answer 5

有一个很好的实际示例 here 和一篇 PDF 文章 here...但是我对 Perl 太生疏了，无法尝试直接实现您的挑战（如您所见，示例和方法都在PDF 使用不那么直接的方法）。

Answer 6

在这种情况下，可以使用memoization。

use strict;
use warnings;

use Memoize;
memoize('fib');

foreach my $i (1..15) {
  print "$i -> ",fib($i),"\n";
}

sub fib {
  my $n = shift;
  return $n if $n < 2;
  fib($n-1) + fib($n-2);
}

Answer 7

这里是根据最初提出的问题量身定制的回答。

任何实现惰性列表（例如 List::Gen、Memoize 等）并允许您提供自己的生成器子例程（我不是指 Python 中的“生成器”）的 perl 模块都将允许您这样做在这个例子中显示。这里延迟生成列表的模块称为 Alef。

#!/usr/bin/perl -w

use strict; use warnings; 
use Alef;

my $fibo;

BEGIN {

    my ($a, $b) = (0, 1);

    $fibo = sub {
        ($a, $b) = ($b, $a+$b);
        $a;
    }
}

my $fibonacci = new Alef($fibo);

foreach my $number ($fibonacci->take(15)){ print $number . "\n"; }

这是输出：

[spl@briareus ~]$ ./fibo.pl 0 1 1 2 3 5 8 13 21 34 55 89 144 233 377

这里使用的惰性列表模块在幕后并没有发生什么神奇的事情。这就是 Alef 的 take 子例程的样子。

sub take {

    my ($self,$n) = (@_);

    my @these = ();

    my $generator = $self->{'generator'};
    for (1..$n){
        push(@these,$self->{'this'});
        $self->{'this'} = &$generator($self->{'this'});
    }
    @these;
}

Answer 8

CPAN 上有一些迭代器/生成器模块可以在这里提供帮助。这是您的示例直接翻译为Coro::Generator 模块：

use 5.016;
use warnings;
use Coro::Generator;

sub gen_fibonacci {
    my $mag = shift;
    generator {
        my ($a, $b) = (0, 1);
        while ($a <= 10 ** $mag) {
            yield $a;
            ($a, $b) = ($b, $a + $b);
        }   
        yield undef;  # stop it!
    };  
}   

my $fibonacci = gen_fibonacci(15);

while (defined (my $number = $fibonacci->())) {
    printf "%17d\n", $number;
}