Windows - for 循环中的 findstr（文件内容）

Question

我有一个文本文件，其中包含类似

的内容

M       test123
S       test
M       abc

等等……

我正在尝试编写一个批处理脚本来执行以下操作：

阅读此文本文件，在每一行中搜索“M       ”（带空格！），然后将找到的行保存在变量中，删除“M       ”并将输出存储在单独的 output.txt 中

所以 output.txt 应该包含以下内容：

test123
S       test
abc

这是我目前所拥有的：

SETLOCAL ENABLEDELAYEDEXPANSION 
SET count=1
FOR /F "tokens=* USEBACKQ" %%F IN (output_whole_check.txt) DO (
SET var!count!=%%F
findstr /lic:"M       " > nul && (set var!count!=var!count!:~8%) || (echo not found)
SET /a count=!count!+1
)
ENDLOCAL

或者有没有更简单的方法来解决这个问题而无需在 Windows 上安装任何额外的东西？

Answer 1

试试这个。它会将所有行回显到 output.txt，并将“M       ”替换为空。

@echo off & setlocal

>output.txt (
    FOR /F "usebackq delims=" %%I IN ("output_whole_check.txt") DO (
        set "line=%%I"
        setlocal enabledelayedexpansion
        echo(!line:M       =!
        endlocal
    )
)

结果：

test123
S       测试
abc

---

或者，如果您的 output_whole_check.txt 非常大，则使用 for /L 循环遍历这些行可能会更快。 for /L 比 for /F 更有效。您只需计算行数即可确定要循环的迭代次数。

@echo off & setlocal

rem // get number of lines in the text file
for /f "tokens=2 delims=:" %%I in ('find /v /c "" "output_whole_check.txt"') do set /a "count=%%I"

<"output_whole_check.txt" >"output.txt" (
    for /L %%I in (1,1,%count%) do (
        set /P "line="
        setlocal enabledelayedexpansion
        echo(!line:M       =!
        endlocal
    )
)

结果是一样的输出。