带有 echo findstr 的批处理文件在 for 循环中不起作用

Question

我有多个来自 for 循环内的 reg 查询的字符串。 我想验证它们中的每一个是否有特定的词，如果有的话，我会采取行动。 我的代码是这样的：

for /l %%g in (0 1 3) do (
        echo HOME%%g
        for /f "tokens=1,2,3*" %%h in ('reg query \\%%c\HKLM\SOFTWARE\ORACLE\HOME%%g /v ORACLE_HOME') do (

            echo HOME%%g
            echo %%j
            echo %%j | findstr /I /R /C:"806"
            if %ERRORLEVEL% equ 0 (
                echo YES
            ) else (
                echo NO
            )

            echo %%j | findstr /C:".isuites."
            if %ERRORLEVEL% equ 0 (
                echo YES
            ) else (
                echo NO
            )

            echo %%j | findstr /I ora90
            if errorlevel 0 (
                echo YES
            ) else (
                echo NO
            )

            echo %%j | findstr /I forms10
            if errorlevel 0 (
                echo YES
            ) else (
                echo NO
            )



        )
    )

问题是它没有验证输出中看到的字符串

HOME0
HOME0
ECHO is off.
YES
YES
YES
YES
HOME0
d:\oracle\806
d:\oracle\806
YES
YES
YES
YES
HOME1
HOME1
ECHO is off. 
YES
YES
YES
YES
HOME1
d:\oracle\iSuites
YES
YES
YES
YES
HOME2
HOME2
ECHO is off.
YES
YES
YES
YES
HOME2
d:\oracle\ora90
YES
YES
d:\oracle\ora90
YES
YES
HOME3
HOME3
ECHO is off.
YES
YES
YES
YES
HOME3
D:\oracle\forms10g
YES
YES
YES
D:\oracle\forms10g
YES

Answer 1

您的代码需要进行一些更正

把for %%h改成

for /f "tokens=1,2,*" %%h in ('reg query \\%%c\HKLM\SOFTWARE\ORACLE\HOME%%g /v ORACLE_HOME ^| find "REG_SZ" ') do ( 

这样，ORACLE_HOME 键名将在 %%h 中，REG_SZ 类型在 %%i 中，文件夹在 %%j 中（我想这就是你想要的）

完成后，下一个问题是errorlevel 检查

当一个代码块（括号内的代码）被解析时，所有的变量读取都被替换为变量在开始执行该块之前的值。所以，如果你在你的代码块中使用%errorlevel%，因为在开始执行之前，这个变量读取已经被替换为变量的值，你将看不到真正的值。

您可以使用延迟扩展（在批处理文件的开头包含setlocal enabledelayedexpansion）并将语法从%errorlevel%更改为!errorlevel!，以向解析器指示变量读取应该延迟到命令执行的那一刻执行。

或者您可以使用if errorlevel n ... 语法。在这种情况下，您应该记住，对于任何大于或等于指定值的 errorlevel 值，条件都将为真。

也就是说，如果errorlevel 为1，则if errorlevel 1 和if errorlevel 0 都将为真。因此，检查错误级别的正确方法是从较大的值到较低的值进行检查

echo %%j | findstr .....
if errorlevel 1 (
    ...
) else (
    ...
)

所以，你的代码应该是这样的

....
....
for /l %%g in (0 1 3) do (
        echo Testing HOME%%g
        echo ---------------------------------
        for /f "tokens=1,2,*" %%h in (
            'reg query \\%%c\HKLM\SOFTWARE\ORACLE\HOME%%g /v ORACLE_HOME 2^>nul ^| find "REG_SZ" '
        ) do (

            echo %%j | findstr /L /C:"806"
            if errorlevel 1 (
                echo NO
            ) else (
                echo YES
            )

            echo %%j | findstr /C:".isuites."
            if errorlevel 1 (
                echo NO
            ) else (
                echo YES
            )

            echo %%j | findstr /I /C:"ora90" 
            if errorlevel 1 (
                echo NO
            ) else (
                echo YES
            )

            echo %%j | findstr /I /C:"forms10"
            if errorlevel 1 (
                echo NO
            ) else (
                echo YES
            )

        )
    )
)

编辑以适应 cmets

如果注册表中不存在某些HOMEn，则不会回显它们。为了“解决”它，将req query的错误输出包含在要解析的数据中，并测试是否找到字符串ERROR:。

for /l %%g in (0 1 3) do (
        echo Testing HOME%%g
        echo ---------------------------------
        for /f "tokens=1,2,*" %%h in (
            'reg query \\%%c\HKLM\SOFTWARE\ORACLE\HOME%%g /v ORACLE_HOME 2^>^&1 ^| findstr /L /C:"REG_SZ" /C:"REG_EXPAND_SZ" /C:"ERROR:" '
        ) do (
            for %%z in ("806" ".isuites." "ora90" "forms10") do (
                (if "%%h"=="ERROR:" (echo() else (echo %%j)) | findstr /i /c:"%%~z"
                if errorlevel 1 (
                    echo NO
                ) else (
                    echo YES
                )
            )
        )
    )
)