【问题标题】:Mathematica large table periodic interpolationMathematica 大表周期插值
【发布时间】:2011-09-05 20:50:38
【问题描述】:

我在 Mathematica 中有一个非常大的表((dimcub-1)^3 个元素),来自逆 FFT。我需要在这张桌子上使用周期性插值。由于周期性插值要求第一个元素和最后一个元素相等,因此我手动创建了一个新的 dim^3 元素表并在我的插值中使用它。它可以工作,但它很丑/很慢,而且由于我多余的中间表,我很快就遇到了内存障碍。谁能告诉我如何通过附加元素将我的旧表变成周期表或使用我的非周期表来制作周期插值函数?这是我目前的一段代码:

mr 1 是新表:

mr1 = Table[  0. , {i, 1, dimcub}, {j, 1, dimcub}, {k, 1, dimcub}];

Do[Do[  Do[   
      mr1[[m, n, k]] = oldtable[[m, n, k]] ;  , {m, 1, 
       dimcub - 1}]; , {n, 1, dimcub - 1}]; , {k, 1, dimcub - 1}]; 
Do[Do[     mr1[[m, n, dimcub]] =  mr1[[m, n, 1]]; 
  mr1[[m, dimcub, n]] =  mr1[[m, 1, n]];  
  mr1[[dimcub, m, n]] =  mr1[[1, m, n]];     , {m, 1, dimcub - 1}];  
 mr1[[n, dimcub, dimcub]] =  mr1[[n, 1, 1]]; 
 mr1[[dimcub, n, dimcub]] =  mr1[[1, n, 1]];  
 mr1[[dimcub, dimcub, n]] =  mr1[[1, 1, n]]; , {n, 1, dimcub - 1}]; 
mr1[[dimcub, dimcub, dimcub]] = mr1[[1, 1, 1]]; 

Remove[oldtable]; 

myinterpolatingfunction = 
 ListInterpolation[mr1, {{1, dimcub}, {1, dimcub}, {1, dimcub}}, 
  InterpolationOrder -> 1, 
  PeriodicInterpolation -> True];

 Remove[mr1];

myinterpolatingfunction 占用更少的内存,并且在我删除旧表后完美运行。任何帮助将不胜感激。

【问题讨论】:

    标签: wolfram-mathematica interpolation


    【解决方案1】:

    Leonid 和 Mr.Wizard 的答案都做得太多了。在 Leonid 的例子中,只有前三行是必要的。为了显示这一点,我将最后 4 个 Sets 更改为 Equals:

    In[65]:= len = 4; oldtable = 
     Partition[Partition[Range[len^3], len], len]
    
    Out[65]= {{{1, 2, 3, 4}, {5, 6, 7, 8}, {9, 10, 11, 12}, {13, 14, 15, 
       16}}, {{17, 18, 19, 20}, {21, 22, 23, 24}, {25, 26, 27, 28}, {29, 
       30, 31, 32}}, {{33, 34, 35, 36}, {37, 38, 39, 40}, {41, 42, 43, 
       44}, {45, 46, 47, 48}}, {{49, 50, 51, 52}, {53, 54, 55, 56}, {57, 
       58, 59, 60}, {61, 62, 63, 64}}}
    
    In[66]:= oldtable[[All, All, -1]] = oldtable[[All, All, 1]];
    oldtable[[All, -1, All]] = oldtable[[All, 1, All]];
    oldtable[[-1, All, All]] = oldtable[[1, All, All]];
    oldtable[[All, -1, -1]] == oldtable[[All, 1, 1]]
    oldtable[[-1, All, -1]] == oldtable[[1, All, 1]]
    oldtable[[-1, -1, All]] == oldtable[[1, 1, All]]
    oldtable[[-1, -1, -1]] == oldtable[[1, 1, 1]]
    
    Out[69]= True
    
    Out[70]= True
    
    Out[71]= True
    
    Out[72]= True
    

    Leonid 的作用如下图所示。他的代码的第 4-6 行做了一些事情,如左侧面板所示:复制已经复制的平面(浅色)的一条线(深色)。第 7 行由右侧面板说明。这是对角相对位置的单元格到单元格复制,其操作不包括在前三个复制动作中的任何一个中,而是它们连续操作的结果。

    【讨论】:

    • 感谢您的插图。我明白你的观点并同意你的看法。 Leonid 进行复制的方式是从我最初的问题中遗留下来的,在该问题中我创建了表的冗余副本以将大小增加 1。摆脱冗余的中间表已经为我节省了足够的内存/时间。
    • @Sjoerd +1 进行漂亮的可视化分析。
    • @yoda +1 表示注意。没想到有人会;-)
    • @Sjoerd 我不知道你来自塞尔维亚! en.wikipedia.org/wiki/File:Flag_of_Serbia_and_Montenegro.svg :)
    • @belisarius 错了! -1 用于使用 Wikipedia 而不是 Tooltip[CountryData[#, "Flag"], #] & /@ CountryData[]。您指的是现已解散的塞尔维亚和黑山国家的国旗。当前的塞尔维亚拥有完全不同的旗帜,mma 知道这一点!无论如何,它既可以是法国国旗,也可以是我国国旗,但需要轮换。
    【解决方案2】:

    您可以通过如下修改原始表来更快、更节省内存:

    oldtable[[All, All, -1]] = oldtable[[All, All, 1]];
    oldtable[[All, -1, All]] = oldtable[[All, 1, All]];
    oldtable[[-1, All, All]] = oldtable[[1, All, All]];
    oldtable[[All, -1, -1]] = oldtable[[All, 1, 1]];
    oldtable[[-1, All, -1]] = oldtable[[1, All, 1]];
    oldtable[[-1, -1, All]] = oldtable[[1, 1, All]];
    oldtable[[-1, -1, -1]] = oldtable[[1, 1, 1]];
    

    这些赋值取代了嵌套循环并且速度更快,而且您不需要内存来存储副本。这是基于Part 命令(数组和通用表达式索引)的扩展矢量化功能,特别是矢量化分配。让您的数字数组采用Packed array 形式也很重要,这通常是这种情况。

    【讨论】:

    • Leonid,你这周的排行榜要火了。 #78 在 StackOverflow 上!
    • @Mr.Wizard 哇,没想到会这样。谢谢你让我知道!但是您忘记了@belisarius 和@yoda,它们在该列表中更高。
    • 他们也不擅长mathematica标签。
    • @Mr.Wizard 你能澄清一下吗?他们都在该列表中的头像下方列出了 Mathematica 标签(但也有其他标签 - 这就是你的意思吗?)
    • 是的。如果您不只回答 Mathematica 问题,那么获得代表分数要容易得多。不是要贬低他们的工作,但这是真的。
    【解决方案3】:

    因为我有点懒,Leonid的解决方法可以写成:

    a = {0, 1}~Tuples~3~SortBy~Tr // Rest;
    
    MapThread[
      (oldtable[[Sequence @@ #]] = oldtable[[Sequence @@ #2]]) &,
      {-a, a} /. 0 -> All
    ];
    

    【讨论】:

    • +1,整体打字少,所以更容易扩展。如果可以的话,我会再为a 的双中缀结构加1。
    • +1。我想展示与原始基于循环的解决方案最接近的对应关系,因为它更容易理解。考虑添加与您所做的非常相似的内容,但为时已晚:)。双中缀确实不错!但是现在,你有责任解释它是如何工作的:)。
    • @rcollyer 谢谢!我经常使用中缀,但我通常将它从我的帖子中删除,因为其他人很少使用它,所以我认为它很难阅读。对我来说,它实际上更容易阅读,因为我知道我正在查看一个带有两个参数的函数,并且因为它以我认为合乎逻辑的方式从左到右阅读。
    • @Sjoerd 准备睡觉了,我什至没有费心去理解问题,我只是翻译了 Leonid 的代码。
    • @Leonid 我并不是说这比你的帖子更好!正如我所说,我有点像个懒人。
    【解决方案4】:

    感谢您的所有回答。我尝试了 leonid 的建议,但是当我打印我的 oldtable 时,它​​仍然是 (dimcub -1)^3 维的。新元素已定义,我可以单独查看它们,但当我打印整个表格时,它们不会显示为旧表格的一部分。所以我最终得到了类似的东西,这正是我需要的:

    oldtable= PadRight[oldtable, {dimcub, dimcub, dimcub}];
    oldtable[[All, All, dimcub]] = oldtable[[All, All, 1]];
    oldtable[[All, dimcub, All]] = oldtable[[All, 1, All]];
    oldtable[[dimcub, All, All]] = oldtable[[1, All, All]];
    oldtable[[All, dimcub, dimcub]] = oldtable[[All, 1, 1]];
    oldtable[[dimcub, All, dimcub]] = oldtable[[1, All, 1]];
    oldtable[[dimcub, dimcub, All]] = oldtable[[1, 1, All]];
    oldtable[[dimcub, dimcub, dimcub]] = oldtable[[1, 1, 1]];
    

    Wizard 的答案对于我的数学水平来说太高级了..

    【讨论】:

    • 我想我们都忽略了一个事实,即您希望新表比旧表大。看我的回答:列昂尼德的答案也适用于你的答案:最后四行是多余的。
    • 我希望新表在每个维度上都比旧表大 1,因为这是我可以将具有匹配端点的表输入到周期性列表插值中的唯一方法。如果有一种方法可以在没有这个中间步骤的情况下进行周期性插值,我宁愿使用它。
    • 您能否修改您的解决方案,以便仅周期性地设置第 2 维和第 3 维而不是第 1 维? [在我的例子中,最后两个维度是空间坐标,第一个是时间]
    猜你喜欢
    • 2013-10-29
    • 2022-11-17
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 2022-01-18
    • 1970-01-01
    相关资源
    最近更新 更多