与 Mathematica 中的拉格朗日插值多项式有关的 Mathematica 中的列表操作

Question

我正在尝试以我可以的方式使用传递给函数的列表

• 获取该列表的长度
• 获取要操作的单个 x 和 y 值

我试图操纵的列表如下所示：

dataTan = Table[{x, Tan[x]}, {x, -1.5, 1.5, .75}];

这个问题是here 所见问题的后续问题。我最终想在mathematica中编写自己的函数，为给定的一组点生成拉格朗日插值多项式

 {{x0, y0}, ... , {xn, yn}}

我需要一些方法来访问上面的点，以便我可以使用下面的代码：

Sum[Subscript[y, j]*Product[If[j != m, (x - Subscript[x, m])/
       (Subscript[x, j] - Subscript[x, m]), 1], {m, 0, k}], {j, 0, k}]

Answer 1

鉴于your last question，我猜你的意思是Lagrange Polynomial，所以

LagrangePoly[pts_?MatrixQ, var_: x] /; MatchQ[Dimensions[pts], {_, 2}] := 
   With[{k = Length[pts]}, Sum[pts[[j, 2]] Product[
     If[j != m, (var - pts[[m, 1]])/(pts[[j, 1]] - pts[[m, 1]]), 1], 
     {m, 1, k}], {j, 1, k}]]

我们可以用正切函数来测试它，

In[2]:= points = Table[{x, Tan[x]}, {x, -1.2, 1.2, .2}]
Out[2]= {{-1.2, -2.57215}, {-1., -1.55741}, {-0.8, -1.02964}, 
         {-0.6, -0.684137}, {-0.4, -0.422793}, {-0.2, -0.20271}, 
         {0., 0.}, {0.2, 0.20271}, {0.4, 0.422793}, 
         {0.6, 0.684137}, {0.8, 1.02964}, {1., 1.55741}, {1.2, 2.57215}}

In[3]:= Plot[Evaluate[Expand[LagrangePoly[points, x]]], {x, -1.2, 1.2}, 
     Epilog -> Point[points]]

这种情况下插值好，与原函数的最大偏差为

In[4]:= FindMaximum[{Abs[Tan[x] - LagrangePoly[points, x]], -1.2<x<1.2}, x]   
Out[4]= {0.000184412, {x -> 0.936711}}

---

另请注意，interpolating polynomials 实际上是内置在 Mathematica 中的：

In[5]:= InterpolatingPolynomial[points, x]-LagrangePoly[points, x]//Expand//Chop
Out[5]= 0

在比较之前我必须扩展它们，因为InterpolatingPolynomial 以高效的HornerForm 返回结果，而我的LagrangePoly 以非常低效的形式返回。

Answer 2

如果您有一个列表l，那么您可以使用First@Dimensions@l 获取该列表的长度。假设列表具有 {{x1,y1},{x2,y2},...} 的形式，那么您只需使用 Part[l,index] 或其简写形式 l[[index]] 即可在位置 index 处获取任何 x 和 y 值。

编辑：如果您想以简单的方式做事，您可以使用Length@l 作为列表长度。