每次调用设置为 nil 的对象引用时不应该调用 Free 引发访问冲突吗？

Question

我收到来自单元 DBXCommon.pas（在 Delphi XE 中）的访问冲突。当我查看代码时，我看到如下内容（在感叹号处）：

function TDBXConnectionFactory.GetConnection(const DBXContext: TDBXContext;
  const ConnectionProperties: TDBXProperties): TDBXConnection;
var
  ConnectionBuilder:  TDBXConnectionBuilder;
  DelegatePath:       TDBXDelegateItem;
  Connection:         TDBXConnection;
  CombinedProperties: TDBXProperties;
begin
  //...
  ConnectionBuilder := TDBXConnectionBuilder.Create;
  Connection        := nil;
  try
    //..lots of setting ConnectionBuilder properties
    ConnectionBuilder.FInputPassword := CombinedProperties[TDBXPropertyNames.Password];
    Connection := ConnectionBuilder.CreateConnection;
    Connection.Open;
    Result     := Connection;
!!  Connection := nil;
  finally
!!  Connection.Free;
    ConnectionBuilder.Free;
  end;
end;

但我在DBXCommon.pas 中看到更多这样的构造（首先分配 Nil，然后是 Free）。这是我不知道的一些构造，还是真的每次调用这段代码都会导致访问冲突？

Answer 1

在nil 引用上调用Free 是安全的，因为它在调用Destroy 之前会检查Self <> nil。请参阅 Allen Bauer 在 Embarcadero forum 为什么引入 TObject.Free 的解释。我在这里只包括相关的报价：

在 TObject 上引入非虚拟 Free 方法的唯一原因是在析构函数中用作以下的简单简写：

if FField <> nil then
  FField.Destroy;

Answer 2

TObject.Free 基本实现为if Self <> nil then Destroy，所以上面的代码应该不会引发任何异常。

Answer 3

在空引用上调用Free 总是安全的。去看看TObject.Free的实现看看为什么。

这段代码是一个工厂函数的例子。它的工作是创建一个类的新实例，但是如果它失败了，它需要确保它在抛出异常时不会泄漏一个半创建的实例，所以它调用Free。当它确定它会成功时，它会将结果的所有权转移给调用者。它仍然调用Free，但如果它已经转移了所有权，那么它最终会在空引用上调用Free，并且不会造成任何伤害。此代码用于转让所有权：

Result := Connection;
Connection := nil;

I 编写工厂函数的方式将取消单独的Connection 变量。我会直接在Result 中构造结果，但如果有异常则释放它，如下所示：

function TDBXConnectionFactory.GetConnection(const DBXContext: TDBXContext;
  const ConnectionProperties: TDBXProperties): TDBXConnection;
var
  ConnectionBuilder:  TDBXConnectionBuilder;
  DelegatePath:       TDBXDelegateItem;
  Connection:         TDBXConnection;
  CombinedProperties: TDBXProperties;
begin
  //...
  ConnectionBuilder := TDBXConnectionBuilder.Create;
  try
    //..lots of setting ConnectionBuilder properties
    ConnectionBuilder.FInputPassword := CombinedProperties[TDBXPropertyNames.Password];
    Result := ConnectionBuilder.CreateConnection;
    try
      Result.Open;
    except
      Result.Free;
      raise;
    end;
  finally
    ConnectionBuilder.Free;
  end;
end;

效果一样。