如何在 AT&T 汇编中正确定位变量？

Question

我正在练习使用程序集（在 AT&T 语法和 gnu/gas 中）编写引导程序。小程序组装链接，然后复制到虚拟磁盘的第一个扇区。 BIOS 会将其加载到0000:7c00，问题就来了。 call hello 将在运行期间从 call 0010 转换为 call 7c10。但是movw $message, %as 不会被重新定位。 ax 仍然是 0026，而不是 7c26。结果是我无法在屏幕上制作Hello World。相反，0000:0026 处的一些随机数据将显示在屏幕上。

如何在引导过程中使其正确？我应该使用某些指令更改 asm 源代码吗？还是我应该更改我的链接脚本？

谢谢！

.text
.global     _start
.code16

_start:
movw    %cs, %ax
movw    %ax, %ds
movw    %ax, %es
call    hello
jmp     .

.org    0x10

hello:
movw    $message, %ax
movw    %ax, %bp
movw    $13, %cx
movw    $0x1301, %ax
movw    $0x000c, %bx
movb    $0, %dl
int     $0x10
ret

message:    
.ascii  "Hello, World!"

.org    0x01fe
.byte   0x55
.byte   0xaa

我使用以下汇编和链接脚本

as -o boot.o boot.s  
    //generate object code

ld -Ttext 0x0 -e _start -s -o boot.out boot.o  
    //relocate .text to 0x0
    //entry is _start

objcopy -O binary -j .text boot.out boot
    //copy .text section to boot

vboxmanage convertfromraw boot boot.vdi --format VDI
    //create vdi for virtual box

Answer 1

我发现主要问题在于您编译代码的方式。

让您的代码工作的正确步骤应该是：

as boot.s -c -o boot.o
ld --oformat binary --Ttext 0x7C00 -o boot.bin boot.o

请注意，正如其他人所说，我将--Ttext 0x7C00 参数传递给ld，以强制它将您的代码重新定位到该地址。

作为额外的建议，请尝试像这样构建您的代码：

.text
.global     _start
.code16

_start:
jmp stage1_start

...

stage1_start:

<your bootloader here>

请注意，这符合 BIOS 代码查看硬盘的方式，因为在 2 个字节（第一个跳转指令的长度）之后，您应该放置磁盘描述表。

此外，您可以使用类似 as 的语法重构您的最后一条指令，如下所示：

. = _start + 0x0200 - 2
.short 0x0AA55

. 变量是位置计数器。查看this page 以获取有关此计数器如何工作的更多信息（在ld 的上下文中，而不是as 的上下文中）。

希望这会有所帮助！