common lisp：宏如何使用以编程方式生成的名称定义其他方法/宏？

Question

我意识到我的代码的某个部分由看起来相似的方法组组成（就像我有多个三重奏：一个辅助函数被其他两个为程序员准备的函数调用）。我正在尝试编写一个宏来为我定义这三个函数，这样我需要做的就是调用宏。但是我的尝试导致 defun 和函数调用将引用字符串而不是生成的名称作为新符号。我做错了什么？

示例（错误代码）

(defmacro def-trio (base-name)
  (let 
    ((helper-name (format nil "helper-~a" base-name))
     (method-1 (format nil "~a-1" base-name))
     (method-2 (format nil "~a-2" base-name)))
    `(progn 
          (defun ,helper-name () 'helper-called)
          (defun ,method-1 () (,helper-name) '1-called)
          (defun ,method-2 () (,helper-name) '2-called))))

现在发生了以下情况：

(def-trio my-trio)

==>

(PROGN (DEFUN "helper-MY-TRIO" () 'HELPER-CALLED)
       (DEFUN "MY-TRIO-1" () ("helper-MY-TRIO") '1-CALLED)
       (DEFUN "MY-TRIO-2" () ("helper-MY-TRIO") '2-CALLED))

另外，在我学会了如何让它工作之后，如果我让这个宏定义其他宏而不是其他函数，是否有任何额外的问题？我读了How do I write a macro-defining macro in common lisp，但我认为我的问题有点不同，因为我在询问以编程方式生成的符号/名称。不过，我愿意接受纠正:) 谢谢！

Answer 1

试试这个：

(defmacro def-trio (base-name)                                         ; changes:
  (let*                                                                ; 3.
    ((package (symbol-package base-name))                              ; 2.
     (helper-name (intern (format nil "HELPER-~a" base-name) package)) ; 1. 4.
     (method-1 (intern (format nil "~a-1" base-name) package))         ; 1.
     (method-2 (intern (format nil "~a-2" base-name) package)) )       ; 1.
    `(progn 
          (defun ,helper-name () 'helper-called)
          (defun ,method-1 () (,helper-name) '1-called)
          (defun ,method-2 () (,helper-name) '2-called) )))

对您的原始定义进行了以下更改——第一个更改是关键：

1. 使用(intern ... package) 将每个计算符号名称与基本名称嵌入到同一个包中。
2. 引入了变量package，该变量绑定到提供的base-name符号的包。
3. 将let 更改为let* 以允许在后续变量中引用新引入的变量package。
4. 将帮助方法的前缀更改为大写以匹配普通 Lisp 符号的约定。

Answer 2

使用INTERN将生成的函数名字符串转为符号。