Common Lisp 在宏中生成变量名

Question

我目前正在学习 Common Lisp，作为该过程的一部分，我正在尝试实现一个通用的井字游戏，其中棋盘可以是任何奇数大小（所以有一个中心正方形）。我到了我正在检查获胜者的地方，并且正在使用这个函数来检查行或列是否有获胜者。

(defun straight-winner-p (board start size)
  (let ((row-player (aref board start 0))
        (row-count 0)
        (col-player (aref board 0 start))
        (col-count 0))

    (loop for step from 0 to (- size 1) do

         (if (equal
              (aref board start step)
              row-player)
             (incf row-count))
         (if (equal
              (aref board step start)
              col-player)
             (incf col-count))
         )
    (format t "row ~a, col ~a~%" row-count col-count)))

格式调用最终将被替换为检查播放器是否为零且计数等于大小。无论如何，我想用宏替换这两个 if。所以，它会是这样的

(check row start step)

宏会生成 if 语句

         (if (equal
              (aref board start step)
              row-player)
             (incf row-count))

然后使用 (check col step start) 调用相同的宏。我似乎无法让宏从行生成行数和行播放器。你会怎么做？

Answer 1

当你已经使用循环宏时，如何使用循环宏中的功能？：

(defun straight-winner-p (board start size)
  (loop :with row-player := (aref board start 0)
        :and col-player := (aref board 0 start)
        :for step :below size
        :count (equal (aref board start step) row-player) :into row-count
        :count (equal (aref board step start) col-player) :into col-count
        :finally (format t "row ~a, col ~a~%" row-count col-count)
                 (return (or (= row-count size) (= col-count size)))))

你如何做你想做的事：

(defmacro check (prefix start step)
  (let ((player (intern (concatenate 'string (string prefix) (string '-player)) (symbol-package prefix)))
        (count (intern (concatenate 'string (string prefix) (string '-count)) (symbol-package prefix))))
    `(when (equal (aref board ,start ,step) ,player)
       (incf ,count))))

虽然已特别注意宏和您的代码最终位于不同的包中并使用所提供符号的包，但如果使用不同的阅读器设置读取文件，它将无法正常工作。如果您编译一个但不编译另一个，它可能无法正常工作。