Mathematica 中奇怪的 Sin[x] 图

Question

我在 Mathematica 7 中随机绘制了一个 Sin[x] 函数，结果如下：

注意大约x = -100 处的可见缺陷。

这是缺陷部分的放大图，清楚地表明 Mathematica 出于某种原因使用的点之间的分辨率要低得多：

有人知道为什么会发生这种情况，为什么只在x = -100 知道吗？

注意：顺便说一下，Wolfram Alpha 也会发生同样的情况。

Answer 1

简答：该功能的默认绘图精度不够，因此按如下方式增加它

Plot[Sin[x], {x, -42 Pi, 42 Pi}, PlotPoints -> 100]

长答案：Plot 通过在有限的点集上评估函数并通过直线连接这些点来工作。可以使用以下命令查看Plot使用的点

Plot[Sin[x], {x, -42 Pi, 42 Pi}, Mesh -> All, PlotStyle -> None, 
 MeshStyle -> Black]

您可以看到，对于您的函数，评估函数的点“错过了峰值”并引入了很大的近似误差。用于选择点位置的算法非常简单，当两个峰的间距比 PlotRange/PlotPoints 更接近时，可能会发生这种情况。

Plot 以 50 个等距点开始，然后在最多 MaxRecursion 阶段中​​插入额外的点。如果您为MaxRecursion 的各种设置绘制区域，您可以看到这个“洞”是如何出现的。

plot1 = Plot[Sin[x], {x, -42 Pi, 42 Pi}, PlotPoints -> 100, 
   PlotStyle -> LightGray];
Table[plot2 = 
   Plot[Sin[x], {x, -42 Pi, 42 Pi}, Mesh -> All, MeshStyle -> Thick, 
    PlotStyle -> Red, MaxRecursion -> k]; 
  Show[plot1, plot2, PlotRange -> {{-110, -90}, {-1, 1}}, 
   PlotLabel -> ("MaxRecursion " <> ToString[k])], {k, 0, 
   5}] // GraphicsColumn

根据 Stan Wagon 的 Mathematica 书，Plot 决定如果两条新线段之间的角度超过 5 度，是否在两个连续点之间的中间添加一个额外点。在这种情况下，绘图在初始点定位时不走运，并且细分不符合该标准。您可以看到，在孔的中心插入一个评估点将产生几乎相同的绘图。

使用Refinement选项增加用于决定何时细分的角度的方法（我从书中得到，但产品中似乎没有记录）

plot1 = Plot[Sin[x], {x, -42 Pi, 42 Pi}, PlotPoints -> 100, 
   PlotStyle -> LightGray];
Show[plot1, 
 Plot[Sin[x], {x, -42 Pi, 42 Pi}, Mesh -> All, MeshStyle -> Thick, 
  PlotStyle -> Red, MaxRecursion -> 3, 
   Method -> {Refinement -> {ControlValue -> 4 \[Degree]}}], 
 PlotRange -> {{-110, -90}, {-1, 1}}]

在这里你可以看到从默认的 5 增加 1 度修复了这个洞。