球拍宏如何将省略号传递给辅助函数？

Question

给定：

(define-syntax (test stx)
  (syntax-case stx ()
    [(_ body ...)
     (with-syntax ([body0 (process-body #'(body ...))])
       #'body0)]))

我应该如何接收助手中的模式和省略号？我什至不确定将 body ... 包裹在 () 内是否正确，但我已经看到它是唯一不会崩溃的东西。

process-body 过程以包含额外 () 的语法结束。我可以尝试将其分解，但我只是想知道正确的方法是什么。

process-body 用一些代码前后包裹了主体模式。而且，与定义类似，我希望能够为宏提供多种形式，而不是一个列表中的所有形式。因此，如果给定 (form1) (form2)，其中 form2 是省略号，则流程主体应该 (do-something) (form1) (form2) (do-something-else)。

即，

(define-for-syntax (process-body body-syntax)
  (with-syntax ([stx body-syntax])
    (syntax/loc body-syntax
      (λ (request)
         stx))))

当然，当我定义内联模板时，我有这个工作，我想我可以在这里做，但有时模板变得笨拙，调用帮助器很好。

非常感谢。

作为尝试 dyoo 的第一个示例的编辑，我提供以下内容：

#lang racket

(define-syntax (test2 stx)
  (syntax-case stx ()
    [(_ body ...)
     (with-syntax ([(body0 ...) (process-body2 #'(body ...))])
       #'(begin body0 ...))]))

(define-for-syntax (process-body2 bodies)
  (with-syntax ([(body ...) bodies])
    (syntax/loc bodies
      (λ (request)
         body ...))))

(test2 (print "hi"))

λ：语法错误

Answer 1

with-syntax 模式的左侧也可以有省略号，因此以下可能：

(define-syntax (test stx)
  (syntax-case stx ()
    [(_ body ...)
     (with-syntax ([(body0 ...) (process-body #'(body ...))])
       #'(begin body0 ...))]))

基本思想是，如果process-body 返回转换后的body 元素，我们可以将它们与begin 一起引入。

---

您的process-body 定义也可以使用带有省略号的with-syntax。所以你可以这样做：

(define-for-syntax (process-body bodies)
  (with-syntax ([(body ...) bodies])
    (syntax/loc bodies
      (λ (request)
         body ...))))

如果这是process-body的定义，我们应该修改test，因为process-body的结果的形状现在是一个完整的lambda表达式，所以我们可以直接返回它的结果：

(define-syntax (test stx)
  (syntax-case stx ()
    [(_ body ...)
     (process-body (syntax/loc stx (body ...)))]))

---

作为一个独立的例子：

#lang racket

(define-syntax (test stx)
  (syntax-case stx ()
    [(_ body ...)
     (process-body 
      (syntax/loc stx (body ...)))]))

(define-for-syntax (process-body bodies)
  (with-syntax ([(body ...) bodies])
    (syntax/loc bodies
      (λ (request)
        (printf "before the body\n")
        body ...
        (printf "after the body\n")))))


;; Let's try it:    
(define p 
  (test (displayln "hello") (displayln "world")))

(p 'should-be-a-request)