为什么 string.join 在 VB.Net 中返回列表对象

Question

我无法理解这两个命令之间的区别，在我看来应该做同样的事情。我已经在下面发布了整个代码，以防有任何不清楚的地方。

我在 Person 类中创建了两个函数，一个返回包含名字、中间名和姓氏的列表，另一个返回名称的串联字符串。我引用了返回列表的函数以将字符串与下面的行连接起来：

FullName = String.Join(" ", Me.Get_NameList())

但是，当我打电话时：

Console.WriteLine(Person1.Print_Name())

我得到的是列表对象而不是字符串：

System.Collections.Generic.List`1[System.String]

如果我将代码更改为如下所示：

    Public Function Print_Name()
        Dim FullNameList As List(Of String) = Me.Get_NameList()
        Dim FullName As String
        FullName = String.Join(" ", FullNameList)
        Return FullName
    End Function

控制台打印：

John Q Doe

为什么我先将列表分配给变量然后加入它会得到不同的答案？这与列表在内存中的存储方式有关吗？

提前感谢您的帮助。

这里是完整的代码：

Imports System
Module Module1
    Sub Main()
        Dim Person1 As New Person("John", "Q", "Doe")
        Console.WriteLine("Get_Name Values")
        Dim g1 As List(Of String) = Person1.Get_NameList()
        Console.WriteLine(String.Join(" ", g1))
        Console.WriteLine("Print_Name Values")
        Console.WriteLine(Person1.Print_Name())
    End Sub
End Module

Class Person
    Private FirstName As String
    Private MiddleName As String
    Private LastName As String
    Public Sub New(ByVal Fn As String, ByVal Mn As String, ByVal Ln As String)
        FirstName = Fn
        MiddleName = Mn
        LastName = Ln
    End Sub
    Public Function Get_NameList()
        Dim NameList As New List(Of String)
        NameList.Add(FirstName)
        NameList.Add(MiddleName)
        NameList.Add(LastName)
        Return NameList
    End Function
    Public Function Print_Name()
        'Dim FullNameList As List(Of String) = Me.Get_NameList()
        Dim FullName As String
        FullName = String.Join(" ", Me.Get_NameList())
        Return FullName
    End Function
End Class

Answer 1

GetNameList 返回一个 Object（因为您没有指定返回类型）。

所以 Join 方法正在获取一个对象。因此，VB.Net 将 Object 转换为 String()，其中一个元素是 Object.ToString()。有时，该方法，特别是如果它是一个老式的 VB 保留方法，会检查传递的对象是否是 IEnumerable，并且只是迭代传递的对象中的对象。但不总是。因此，严格和显式关闭会导致非常奇怪且难以发现的错误。这两件事应该只在非常特殊的情况下才应该关闭，在这种情况下，您希望所有的灵活性都可以关闭它们，并且您已经准备好处理由此产生的奇怪现象。

将Get_NameList的返回类型改为List(Of String)

并打开选项 Strict ON 和 Option Explicit On 以查看您的其他问题。

Answer 2

如果你改变这一行：

Public Function Get_NameList()

到

Public Function Get_NameList() AS List(Of String)

还有这一行

Public Function Print_Name()

到

Public Function Print_Name() as string

会有用的