存储和检索某个类型类的对象 - 可能吗？如果是，如何？

Question

假设我有一些类型类Foo 和一些数据类型FooInst 是Foo 的实例：

class Foo a where
  foo :: a -> String

data FooInst = FooInst String

instance Foo FooInst where
    foo (FooInst s) = s

现在，我想定义一个数据类型来存储一个对象，该对象的类型在 Foo 类型类中，并且能够从该数据类型中提取该对象并使用它。

我发现的唯一方法是使用 GADTs 和 Rank2Types 语言扩展并像这样定义数据类型：

data Container where
  Container :: { content :: Foo a => a } -> Container

但是，问题是，我无法使用 content 选择器将内容从容器中取出：

cont :: Container
cont = Container{content = FooInst "foo"}

main :: IO ()
main = do
  let fi = content cont
  putStrLn $ foo fi

导致编译错误

Cannot use record selector ‘content’ as a function due to escaped type variables
Probable fix: use pattern-matching syntax instead

但是当我将let ... 行修改为

let Conainer fi = cont

我遇到了一个相当有趣的错误

My brain just exploded
I can't handle pattern bindings for existential or GADT data constructors.
Instead, use a case-expression, or do-notation, to unpack the constructor.

如果我再次尝试修改 let ... 行以使用 case-expression

let fi = case cont of
           Container x -> x

我得到一个不同的错误

Couldn't match expected type ‘t’ with actual type ‘a’
  because type variable ‘a’ would escape its scope
This (rigid, skolem) type variable is bound by
  a pattern with constructor
    Container :: forall a. (Foo a => a) -> Container,
  in a case alternative
  at test.hs:23:14-24

那么，我怎样才能存储一个类型分类的东西并取回它？

Answer 1

与：

data Container where
    Container :: {content :: Foo a => a} -> Container

类型类约束甚至没有强制执行。那就是

void :: Container
void = Container {content = 42 :: Int}

类型检查，即使42 :: Int 不是 Foo 的实例。

但如果你改为：

data Container where
    Container :: Foo a => {content :: a} -> Container

1. 您不再需要 Rank2Types 语言扩展。
2. 强制类型类约束；因此上面的void 示例将不再进行类型检查。

3. 此外，您可以通过模式匹配对内容调用foo（或任何其他带有签名Foo a => a -> ...的函数）：

   case cont of Container {content = a} -> foo a
   

Answer 2

例如

main :: IO ()
main = do
  case cont of
    Container fi -> putStrLn $ foo fi

您需要将您对存在类型字段fi 的使用封装在一个类型不依赖于fi 类型的表达式中；这里是putStrLn $ foo fi，其类型为IO ()。

这个例子没什么用，因为你唯一能对Container的content字段做的就是调用foo，所以你最好在构造容器之前调用foo并给出字段类型String。但更有趣的是，Foo 的操作具有 a -> a -> a 之类的类型，或者 Container 具有多个字段，其类型涉及相同的存在量化变量等。