如何检查对象是否为某种类型

Question

我将各种对象传递给子例程以运行相同的进程，但每次都使用不同的对象。例如，在一种情况下，我使用 ListView，而在另一种情况下，我正在传递 DropDownList。

我想检查传递的对象是否是 DropDownList，如果是，则执行一些代码。我该怎么做？

到目前为止我的代码不起作用：

Sub FillCategories(ByVal Obj As Object)
    Dim cmd As New SqlCommand("sp_Resources_Categories", Conn)
    cmd.CommandType = CommandType.StoredProcedure
    Obj.DataSource = cmd.ExecuteReader
    If Obj Is System.Web.UI.WebControls.DropDownList Then

    End If
    Obj.DataBind()
End Sub

Answer 1

在 VB.NET 中，您需要使用GetType method 来检索对象实例的类型，并使用GetType() operator 来检索另一个已知类型的类型。

一旦有了这两种类型，您就可以使用Is 运算符简单地比较它们。

所以你的代码实际上应该这样写：

Sub FillCategories(ByVal Obj As Object)
    Dim cmd As New SqlCommand("sp_Resources_Categories", Conn)
    cmd.CommandType = CommandType.StoredProcedure
    Obj.DataSource = cmd.ExecuteReader
    If Obj.GetType() Is GetType(System.Web.UI.WebControls.DropDownList) Then

    End If
    Obj.DataBind()
End Sub

您也可以使用TypeOf operator 代替GetType 方法。请注意，这会测试您的对象是否与给定类型兼容，而不是测试它是否是同一类型。看起来像这样：

If TypeOf Obj Is System.Web.UI.WebControls.DropDownList Then

End If

---

完全无关紧要的吹毛求疵： 在编写 .NET 代码（VB.NET 或 C#）时，参数名称传统上是驼峰式（这意味着它们总是以小写字母开头） .这使得它们一目了然地与类、类型、方法等区分开来。

Answer 2

与 Cody Gray 的回复有关的更多细节。由于我花了一些时间来消化它，但它可能对其他人有用。

首先，一些定义：

1. 有TypeName，它们是对象、接口等类型的字符串表示形式。例如，Bar 是Public Class Bar 或Dim Foo as Bar 中的TypeName。 TypeNames 可以看作是代码中使用的“标签”，用于告诉编译器在字典中查找哪个类型定义，其中将描述所有可用类型。
2. 有 System.Type 包含值的对象。这个值表示一个类型；就像String 会接受一些文本或Int 会接受一个数字，只是我们存储的是类型而不是文本或数字。 Type 对象包含类型定义及其对应的 TypeName。

二、理论：

1. Foo.GetType() 返回一个 Type 对象，其中包含变量 Foo 的类型。换句话说，它告诉您Foo 是一个实例。
2. GetType(Bar) 返回一个 Type 对象，其中包含 TypeName Bar 的类型。

3. 在某些情况下，对象的类型 Cast 与对象最初实例化的类型不同。在以下示例中，MyObj 是 Integer 转换为 Object：

   Dim MyVal As Integer = 42 Dim MyObj As Object = CType(MyVal, Object)

那么，MyObj 是 Object 类型还是 Integer 类型？ MyObj.GetType() 会告诉你这是一个Integer。

4. 但是Type Of Foo Is Bar 功能出现了，它允许您确定变量Foo 与类型名称Bar 兼容。 Type Of MyObj Is Integer 和 Type Of MyObj Is Object 都将返回 True。在大多数情况下，如果变量属于 TypeName 或派生自它的 Type，TypeOf 将指示变量与 TypeName 兼容。 更多信息在这里：https://docs.microsoft.com/en-us/dotnet/visual-basic/language-reference/operators/typeof-operator#remarks

下面的测试很好地说明了每个提到的关键字和属性的行为和用法。

Public Sub TestMethod1()

    Dim MyValInt As Integer = 42
    Dim MyValDble As Double = CType(MyValInt, Double)
    Dim MyObj As Object = CType(MyValDble, Object)

    Debug.Print(MyValInt.GetType.ToString) 'Returns System.Int32
    Debug.Print(MyValDble.GetType.ToString) 'Returns System.Double
    Debug.Print(MyObj.GetType.ToString) 'Returns System.Double

    Debug.Print(MyValInt.GetType.GetType.ToString) 'Returns System.RuntimeType
    Debug.Print(MyValDble.GetType.GetType.ToString) 'Returns System.RuntimeType
    Debug.Print(MyObj.GetType.GetType.ToString) 'Returns System.RuntimeType

    Debug.Print(GetType(Integer).GetType.ToString) 'Returns System.RuntimeType
    Debug.Print(GetType(Double).GetType.ToString) 'Returns System.RuntimeType
    Debug.Print(GetType(Object).GetType.ToString) 'Returns System.RuntimeType

    Debug.Print(MyValInt.GetType = GetType(Integer)) '# Returns True
    Debug.Print(MyValInt.GetType = GetType(Double)) 'Returns False
    Debug.Print(MyValInt.GetType = GetType(Object)) 'Returns False

    Debug.Print(MyValDble.GetType = GetType(Integer)) 'Returns False
    Debug.Print(MyValDble.GetType = GetType(Double)) '# Returns True
    Debug.Print(MyValDble.GetType = GetType(Object)) 'Returns False

    Debug.Print(MyObj.GetType = GetType(Integer)) 'Returns False
    Debug.Print(MyObj.GetType = GetType(Double)) '# Returns True
    Debug.Print(MyObj.GetType = GetType(Object)) 'Returns False

    Debug.Print(TypeOf MyObj Is Integer) 'Returns False
    Debug.Print(TypeOf MyObj Is Double) '# Returns True
    Debug.Print(TypeOf MyObj Is Object) '# Returns True


End Sub

---

编辑

您还可以使用Information.TypeName(Object) 来获取给定对象的TypeName。例如，

Dim Foo as Bar
Dim Result as String
Result = TypeName(Foo)
Debug.Print(Result) 'Will display "Bar"