VBA：从 Outlook 中与 Access 交互

Question

我正在尝试在 Outlook 中创建一些与 Access 数据库中包含的表交互的自定义​​按钮。到目前为止，我的按钮在 Outlook 中工作，运行代码来实例化自定义数据访问类，该类依次处理打开和关闭与数据库的连接。据我所知，这很有效。

但是，我什至无法从此类中执行简单的选择查询。谁能帮我理解为什么下面的代码可能不起作用？我总是以一个没有行的记录集结束，但如果我使用 Access 查询设计器运行相同的 sql，它就可以正常工作。

Public Function GetJobID(ByVal xEmailID As String) As Integer
'Returns the JobID associated with a given EmailID from the email link table.
'Returns a fail constant if no link exists.
    Dim rs As ADODB.Recordset
    Dim sql As String

    'Exit if not connected.
    'Cast to boolean because VBA doesn't recognise connection state integer as boolean.
    If Not CBool(mConn.State) Then
        GetJobID = RESULT_FAIL_INTEGER
        Exit Function
    End If

    sql = "SELECT [JobID] FROM [EMAIL_LINK_TABLE] WHERE [EmailID]='xEmailID'"
    sql = Replace(sql, "EMAIL_LINK_TABLE", EMAIL_LINK_TABLE)
    sql = Replace(sql, "xEmailID", xEmailID)

    On Error Resume Next
    Set rs = mConn.Execute(sql)

    If rs.RecordCount > 0 Then
        GetJobID = rs(1).Value
    Else
        GetJobID = RESULT_FAIL_INTEGER
    End If

End Function

Answer 1

我看到您已将问题追踪到 .RecordCount 返回 -1。

这是动态游标的标准行为，来自the docs：

Recordset 对象的游标类型影响是否可以确定记录数。对于只进游标，RecordCount 属性将返回 -1；静态或键集游标的实际计数；以及 -1 或动态游标的实际计数，具体取决于数据源。

当然，您可以修改代码以使用静态游标，但这会影响性能。相反，要测试您的记录集中是否有记录，请使用.EOF（一种返回布尔值以指示记录集当前是否位于文件末尾的方法）。当只需要加载第一个记录时，这将使您的代码不必加载所有记录：

Public Function GetJobID(ByVal xEmailID As String) As Integer
'Returns the JobID associated with a given EmailID from the email link table.
'Returns a fail constant if no link exists.
    Dim rs As ADODB.Recordset
    Dim sql As String

    'Exit if not connected.
    'Cast to boolean because VBA doesn't recognise connection state integer as boolean.
    If Not CBool(mConn.State) Then
        GetJobID = RESULT_FAIL_INTEGER
        Exit Function
    End If

    sql = "SELECT [JobID] FROM [EMAIL_LINK_TABLE] WHERE [EmailID]='xEmailID'"
    sql = Replace(sql, "EMAIL_LINK_TABLE", EMAIL_LINK_TABLE)
    sql = Replace(sql, "xEmailID", xEmailID)

    On Error Resume Next 
    Set rs = mConn.Execute(sql)

    If Not rs.EOF Then
        GetJobID = rs(0).Value
    Else
        GetJobID = RESULT_FAIL_INTEGER
    End If

End Function