从非常规的日期和时间字符串中获取平均值答案

【问题标题】：Getting an average from an unconventional date and time string从非常规的日期和时间字符串中获取平均值
【发布时间】：2021-04-03 06:55:27
【问题描述】：

我有一个 Alexa 例程，其中我说晚安的日期/时间会在 Google 表格中进行跟踪 - 这样我就可以看到我真正上床睡觉的时间。是的，现在一切都可以跟踪和测量！

但条目是超级奇怪且无用的字符串，而不是日期和时间：

样本数据：

January 23, 2021 at 11:29PM
January 25, 2021 at 12:03AM
January 25, 2021 at 11:27PM
January 26, 2021 at 11:17PM

Alexa 只是将这些非常规的日期/时间字符串转储到 A1-A 中？？？在第一个选项卡上。

我的目标 - 显示我每个月的平均就寝时间。通常我可以找到答案，但我无法将这些转换为月/年和时间，更不用说找到平均它们的方法了。

转向那些比我更疯狂的人！

一如既往地受到赞赏。

【问题讨论】：

Alexa 正在将日期直接转储到 Google 表格中，还是您？当您单击条目时，它会在公式栏中显示什么？

标签： google-sheets

【解决方案1】：

您可以试试这个（在 C1 中，因为您的数据从 A2:A 开始）：

更新：

= QUERY(ARRAYFORMULA(
            IF(LEN(A2:A), {
                MONTH(REGEXEXTRACT(A2:A, "\D+") & 1),
                REGEXEXTRACT(A2:A, "\D+"),
                IF(TIMEVALUE(REGEXEXTRACT(A2:A, "\d+:\d+.*")) > 0.5,
                    TIMEVALUE(REGEXEXTRACT(A2:A, "\d+:\d+.*")),
                    TIMEVALUE(REGEXEXTRACT(A2:A, "\d+:\d+.*")) + 1)
            }, "")),
        "Select Col1,Col2 ,avg(Col3) where Col1 is not null 
        group by Col1, Col2 Order By Col1 asc label Col1 '#', Col2 'Month', avg(Col3)
        'Average bedtime'
        ")

电子表格演示：HERE

【讨论】：

你好，纳布努布。看我的回答。与更简单的公式结果相同
确实如此。我删除了我的答案。
这很棒，成功了。显然我的平均睡觉时间比我想象的要晚得多。很高兴知道！感谢您对此的真正实质性回应，Nabnub！
如果回复对您有用，您可以将其标记为已接受并投票，它可以帮助其他人从您的问题和答案中找到灵感。

【解决方案2】：

您说您的原始数据字符串运行 A1:A。在这种情况下，您可以将以下内容放在单元格 B1 中（其中 Col B 和 Col C 均为空）：

=FILTER(SPLIT(A:A," at ",0,1),A:A<>"")

这将为 Col A 中的每个字符串在 Col B 中创建一个实际日期，并在 Col C 中创建一个实时时间。从那里，您可以轻松地执行其他功能。例如，假设您在 B1 中有上述公式，您可以将以下内容放入 E1 中：

=ArrayFormula(QUERY(FILTER({DATE(YEAR(B:B),MONTH(B:B),1),IF(C:C<0.5,C:C+1,C:C)*1},A:A<>""),"Select Col1, AVG(Col2) GROUP BY Col1 LABEL AVG(Col2) ''"))

...然后格式化 Col E (Format > Number > More Formats > Custom number format > mmm yyyy) 和 Col F (Format > Number >更多格式 > 自定义数字格式 > h:mm am/pm).

【讨论】：