Create PROC P_viewPage
![]()
asp调用简单例子:
<% Option Explicit%>
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312" />
<style>
body{
font-family: "宋体";
font-size: 9pt;
text-decoration: none;
line-height: 150%;
margin: 0px;
background-color: #A8C2F9;
}
a:link { color: #000000; text-decoration: none}
a:visited { color: #000000; text-decoration: none}
a:hover { color: #3333ff; text-decoration: none}
</style>
</head>
<body>
<%
Dim strDbConn , Conn
strDBConn = "Provider=SQLOLEDB.1;Password=xxxxxxxxxx;Persist Security Info=True; " & _
"User ID=sa;Initial Catalog=DB_xxx;Data Source=RDG_NZ"
Set Conn = Server.CreateObject("ADODB.Connection")
Dim startime
startime=timer()
Function PageView(pagecount,pagesize,page,recordercount)
'pagecount 总页数
'pagesize 每页显示数量
'page 当前是第几页
'recordercount 总记录数量
'get方式传值： pagecount:总页数 recordercount:总记录数量
pagecount = Clng(pagecount)
pagesize = Clng(pagesize)
page = Clng(page)
recordercount = Clng(recordercount)
Dim query, a, x, temp ,action
action = "http://" & Request.ServerVariables("HTTP_HOST") _
& Request.ServerVariables("SCRIPT_NAME")
query = Split(Request.ServerVariables("QUERY_STRING"), "&")
For Each x In query
a = Split(x, "=")
If StrComp(a(0), "page", vbTextCompare) <> 0 and _
StrComp(a(0), "pagecount", vbTextCompare) <> 0 _
and StrComp(a(0), "recordercount", vbTextCompare) <> 0 Then
temp = temp & a(0) & "=" & a(1) & "&"
End If
Next
PageView = "<form method=get onsubmit=""document.location = '" _
& action & "?" & temp & "Page='+this.page.value;return false;"">"
If page<=1 then
PageView = PageView & "[首页] [上一页] "
Else
PageView = PageView & "[<a href=" & action & "?" & temp & "Page=1>首页</a>] "
PageView = PageView & "[<a href=" & action & "?" & temp & "Page=" & (Page-1) & _
"&pagecount="& pagecount &"&recordercount="& recordercount &">上一页</a>] "
End If
If page>=pagecount then
PageView = PageView & "[下一页] [尾页] "
Else
PageView = PageView & "[<a href=" & action & "?" & temp & "Page=" & (Page+1) & _
"&pagecount="& pagecount &"&recordercount="& recordercount &">下一页</a>] "
PageView = PageView & "[<a href=" & action & "?" & temp & "Page="& pagecount & _
"&pagecount="& pagecount &"&recordercount="& recordercount &">尾页</a>] "
End If
PageView = PageView & "[页次:<font color=red>" & page & "</font>/" & pageCount
PageView = PageView & "] [共" & recordercount & "条 <font color=red>"& pagesize & _
"</font>条/页]"
PageView = PageView & " 转到" & "<input name=page size=4 value=" & page & _
">" & "页<input type=submit value=go></form>"
End Function
Dim TableName '表名
Dim FieldList '显示列名，如果是全部字段则为*
Dim PrimaryKey '单一主键或唯一值键
Dim Where '查询条件 不含'where'字符，如id>10 and len(userid)>9
Dim order '排 序 不含'order by'字符，如id asc,userid desc，必须指定asc或desc
'注意当Dim SortType=3时生效，记住一定要在最后加上主键，否则会让你比较郁闷
Dim SortType '排序规则 1:正序asc 2:倒序desc 3:多列排序方法
Dim RecorderCount '记录总数 0:会返回总记录
Dim PageSize '每页输出的记录数
Dim PageIndex '当前页数
Dim TotalCount '记返回总记录
Dim TotalPageCount '记返回总页数
TableName = "T_TEST"
FieldList = "*"
PrimaryKey = "id"
Where = "id>"& request("id")
order = "id asc"
SortType = "1"
If Request("recordercount")="" Then
RecorderCount = "0"
Else
RecorderCount = Request("recordercount")
End If
PageSize = "10"
If Request("page")="" Then
PageIndex = "1"
Else
PageIndex = Request("page")
End If
TotalCount = RecorderCount
If Request("pagecount")="" Then
TotalPageCount = "1"
Else
TotalPageCount = Request("pagecount")
End If
Dim Cmd ,rs
Set Cmd = Server.CreateObject("ADODB.Command")
Set Rs = Server.CreateObject("ADODB.Recordset")
Conn.Open strDBConn
With Cmd
.CommandText = "P_viewPage"
.CommandType = 4
.CommandTimeout = 0
.ActiveConnection = Conn
.Parameters.Append .CreateParameter("@TableName",200,1,200,TableName)
.Parameters.Append .CreateParameter("@FieldList",200,1,2000,FieldList)
.Parameters.Append .CreateParameter("@PrimaryKey",200,1,100,PrimaryKey)
.Parameters.Append .CreateParameter("@Where",200,1,2000,Where)
.Parameters.Append .CreateParameter("@Order",200,1,1000,Order)
.Parameters.Append .CreateParameter("@SortType",3,1,,SortType)
.Parameters.Append .CreateParameter("@RecorderCount",3,1,,RecorderCount)
.Parameters.Append .CreateParameter("@PageSize",3,1,,PageSize)
.Parameters.Append .CreateParameter("@PageIndex",3,1,,PageIndex)
.Parameters.Append .CreateParameter("@TotalCount",3,3,,TotalCount)
.Parameters.Append .CreateParameter("@TotalPageCount",3,3,,TotalPageCount)
Set rs = .Execute
If Not rs.Eof Then
while not rs.Eof
Rem 输出你的记录集内容
Response.Write rs(0) & " || " & rs(1) & "<br>"
rs.MoveNext
wend
End If
rs.Close
TotalCount = .Parameters("@TotalCount")
TotalPageCount = .Parameters("@TotalPageCount")
End With
Set Rs = Nothing
Set Cmd = Nothing
Conn.Close
Set Conn = Nothing
Response.write PageView(TotalPageCount,pagesize,PageIndex,TotalCount)
Dim endtime
endtime=timer()
%>
<br>页面执行时间：<%=FormatNumber((endtime-startime)*1000,3)%>毫秒
</body>
</html>
相关文章：