SAP ABAP2XLSX Sheet表之间的跳转之ZDEMO_EXCEL4

ABAP2XLSX Sheet表之间跳转、Sheet表颜色设置、SHeet表隐藏、Excel页眉页脚设置、Excel 打印设置 ZDEMO_EXCEL4

代码：

DATA: lo_excel                TYPE REF TO zcl_excel,
      lo_worksheet            TYPE REF TO zcl_excel_worksheet,

      lo_hyperlink            TYPE REF TO zcl_excel_hyperlink,

      lv_tabcolor             TYPE zexcel_s_tabcolor,

      ls_header               TYPE zexcel_s_worksheet_head_foot,
      ls_footer               TYPE zexcel_s_worksheet_head_foot.

CONSTANTS: gc_save_file_name TYPE string VALUE \'zdemo_excel.xlsx\'.
INCLUDE zdemo_excel_outputopt_incl.


START-OF-SELECTION.

  " Creates active sheet
  CREATE OBJECT lo_excel.

  " Get active sheet
  lo_worksheet = lo_excel->get_active_worksheet( ).
  lo_worksheet->set_title( ip_title = \'Sheet1\' ).
  lo_worksheet->zif_excel_sheet_properties~selected = zif_excel_sheet_properties=>c_selected.
  lo_worksheet->set_cell( ip_column = \'B\' ip_row = 2 ip_value = \'Sheet1\' ).

  lv_tabcolor-rgb = zcl_excel_style_color=>create_new_argb( ip_red   = \'FF\'
                                                            ip_green = \'00\'
                                                            ip_blu   = \'00\' ).  "设置Sheet颜色
  lo_worksheet->set_tabcolor( lv_tabcolor ).

  lo_hyperlink = zcl_excel_hyperlink=>create_internal_link( iv_location = \'Sheet2!B2\' ).
  lo_worksheet->set_cell( ip_column = \'B\' ip_row = 3 ip_value = \'双击跳转到Sheet2\' ip_hyperlink = lo_hyperlink ).  "设置内部跳转按钮在B3单元格，跳转到Sheet2!B2

  " 页面打印设置
  lo_worksheet->sheet_setup->set_page_margins( ip_header = \'1\' ip_footer = \'1\' ip_unit = \'cm\' ).  "页眉页脚边距1cm
  lo_worksheet->sheet_setup->black_and_white   = \'X\'.   "黑白打印
  lo_worksheet->sheet_setup->fit_to_page       = \'X\'.  " 调整行列长宽
  lo_worksheet->sheet_setup->fit_to_height     = 0.    " fit_to_page = X 时生效
  lo_worksheet->sheet_setup->fit_to_width      = 2.    " fit_to_page = X 时生效
  lo_worksheet->sheet_setup->orientation       = zcl_excel_sheet_setup=>c_orientation_landscape.
  lo_worksheet->sheet_setup->page_order        = zcl_excel_sheet_setup=>c_ord_downthenover.
  lo_worksheet->sheet_setup->paper_size        = zcl_excel_sheet_setup=>c_papersize_a4. "A4纸
  lo_worksheet->sheet_setup->scale             = 80.   "  fit_to_page = SPACE 时生效

  " 设置页眉页脚内容
  ls_header-right_value = \'print date &D\'.    "显示结果  print date  20201008
  ls_header-right_font-size = 8.
  ls_header-right_font-name = zcl_excel_style_font=>c_name_arial.

  ls_footer-left_value = \'&Z&F\'.  "显示结果  Path/Filename C:\Users\Administrator\Desktop\zdemo_excel.xlsx
  ls_footer-left_font = ls_header-right_font.
  ls_footer-right_value = \'page &P of &N\'. "显示结果  page 当前页编号 of 下一页编号
  ls_footer-right_font = ls_header-right_font.

  lo_worksheet->sheet_setup->set_header_footer( ip_odd_header  = ls_header
                                                ip_odd_footer  = ls_footer ).


  lo_worksheet = lo_excel->add_new_worksheet( ).
  lo_worksheet->set_title( ip_title = \'Sheet2\' ).
* Set color to tab with sheetname   - Green
  lv_tabcolor-rgb = zcl_excel_style_color=>create_new_argb( ip_red   = \'00\'
                                                            ip_green = \'FF\'
                                                            ip_blu   = \'00\' ).
  lo_worksheet->set_tabcolor( lv_tabcolor ).
  lo_worksheet->zif_excel_sheet_properties~selected = zif_excel_sheet_properties=>c_selected.
  lo_worksheet->set_cell( ip_column = \'B\' ip_row = 2 ip_value = \'Sheet2\' ).
  lo_hyperlink = zcl_excel_hyperlink=>create_internal_link( iv_location = \'Sheet1!B2\' ).
  lo_worksheet->set_cell( ip_column = \'B\' ip_row = 3 ip_value = \'双击跳转到Sheet1\' ip_hyperlink = lo_hyperlink ).
  lo_worksheet->set_cell( ip_column = \'B\' ip_row = 4 ip_value = \'Sheet3 is Hidden\' ).

  lo_worksheet->sheet_setup->set_header_footer( ip_odd_header  = ls_header
                                                ip_odd_footer  = ls_footer ).

  lo_worksheet = lo_excel->add_new_worksheet( ).
  lo_worksheet->set_title( ip_title = \'Sheet3\' ).
  lv_tabcolor-rgb = zcl_excel_style_color=>create_new_argb( ip_red   = \'00\'
                                                            ip_green = \'00\'
                                                            ip_blu   = \'FF\' ).
  lo_worksheet->set_tabcolor( lv_tabcolor ).
  lo_worksheet->zif_excel_sheet_properties~hidden = zif_excel_sheet_properties=>c_hidden.   "设置隐藏Sheet

  lo_worksheet->sheet_setup->set_header_footer( ip_odd_header  = ls_header
                                                ip_odd_footer  = ls_footer ).

  lo_worksheet = lo_excel->add_new_worksheet( ).
  lo_worksheet->set_title( ip_title = \'Sheet4\' ).
* Set color to tab with sheetname   - other color
  lv_tabcolor-rgb = zcl_excel_style_color=>create_new_argb( ip_red   = \'00\'
                                                            ip_green = \'FF\'
                                                            ip_blu   = \'FF\' ).
  lo_worksheet->set_tabcolor( lv_tabcolor ).
  lo_worksheet->set_cell( ip_column = \'B\' ip_row = 2 ip_value = \'单元格B3值为0\' ).
  lo_worksheet->set_cell( ip_column = \'B\' ip_row = 3 ip_value = 0 ).
  lo_worksheet->zif_excel_sheet_properties~show_zeros = zif_excel_sheet_properties=>c_hidezero.   "设置不显示值为0的单元格

  lo_worksheet->sheet_setup->set_header_footer( ip_odd_header  = ls_header
                                                ip_odd_footer  = ls_footer ).

  lo_excel->set_active_sheet_index_by_name( \'Sheet2\' ).       "设置默认显示的SHeet名为Sheet2

*** Create output
  lcl_output=>output( lo_excel ).
运行程序后，输出选项：

Save to Frontend 前台输出，下载到电脑
Save to Backend 后台输出
Direct Display 直接输出，在SAP GUI显示Excel表
Send Via Email 发送至邮箱
1-1
1-2
1-3
1-4
直接输出-前台显示结果：

1-5