纹理最基础的目的就是用一张图片控制模型的外观，使用纹理映射技术，把一张图附在模型表面，逐纹素的控制模型的颜色。
美术人员会在建模软件中利用纹理展开技术把纹理映射坐标存储在每个顶点上。
纹理映射坐标定义了该顶点在纹理中对应的2D坐标。我们用二维变量(u, v)来表示这些坐标，所以也被称为UV坐标。
不管纹理大小如何，UV坐标会被归一化到[0, 1]范围内。当然，纹理采样使用的纹理坐标不一定是[0, 1]范围内。这取决于纹理的平铺模式。
OpenGL和DirectX在二维纹理空间的坐标差异。OpenGL原点位于左下角，DirectX位于左上角，Unity默认OpenGL的左下角为原点，当然如果跨平台我们也需要手动判断。如下图所示：
单张纹理
我们通常会用一张纹理代替物体的漫反射颜色。下面我们实现一个最简单的纹理。
准备工作：
（1）新建一个材质，命名SingleTexMat。
（2）新建一个UnityShader,命名为SingleTex。把SingleTex赋值给SingleTexMat。
（3）创建胶囊体，并把材质赋值给该胶囊体。
（4）保存场景，并开始下面shader代码。
Shader "Unlit/SingleTex"
{
//为了使用纹理，我们需要在Properties语义块中添加一个纹理属性
Properties
{
_Color ("Color Tint", Color) = (1, 1, 1, 1)//为了控制物体整体色调，声明一个_Color属性
_MainTex ("Main Tex", 2D) = "white" {} //“white”是内置纹理的名字
_Specular ("Specular", Color) = (1, 1, 1, 1)
_Gloss ("Gloss", Range(8.0, 256)) = 20
}
SubShader
{
Pass
{
Tags { "LightMode"="ForwardBase" }//指明该Pass的光照模式，LightMode标签是Pass标签中的一种，用于定义该pass在Unity的光照流水线中的角色
CGPROGRAM
#pragma vertex vert//定义顶点着色器和片元着色器
#pragma fragment frag
//使用Unity内置的一些变量，如_LightColor0,还需要包含进Unity的内置文件Lighting.cginc
#include "Lighting.cginc"
//需要在Cg代码片中声明和上述属性类型相匹配的变量，以便和材质面板中的属性建立联系
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;//为纹理类型的属性声明一个float4类型的变量
fixed4 _Specular;
float _Gloss;
//定义顶点着色器的输入和输出结构体
struct a2v
{
float4 vertex : POSITION;
float3 normal:NORMAL;
float4 texcoord: TEXCOORD0;
};
struct v2f
{
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float3 worldPos : TEXCOORD1;
float2 uv:TEXCOORD2;
};
//上面代码中，首先在a2v结果体中使用TEXCOORD0语义声明了一个新的变量texcood,
//这样Unity就会将模型的第一组纹理坐标存储到该变量中。
//然后，在v2f结构体中添加了用于存储纹理坐标的变量uv,y以便在片元着色器中使用该坐标进行纹理采样。
//定义顶点着色器。
//使用纹理属性_MainTex_ST来对顶点纹理坐标进行变换，得到最终的纹理坐标。
//计算过程，首先使用缩放属性_MainTex_ST.xy对顶点纹理坐标进行缩放，然后再使用偏移属性_MainTex_ST.zw对结果进行偏移。
//Unity提供了一个内置宏TRANSFORM_TEX来帮我们计算上述过程。
v2f vert (a2v v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldPos = mul(_Object2World, v.vertex).xyz;
o.uv = v.texcoord.xy *_MainTex_ST.xy + _MainTex_ST.zw;
//o.uv = TRANSFORM_TEX(v.uv, _MainTex);
return o;
}
//TRANSFORM_TEX是在UnityCG.cginc中定义的。它接受两个参数，第一个参数顶点纹理坐标，第二个是纹理名，在它的实现中，将利用纹理名_ST的方式来计算变换后的纹理坐标。
//#define TRANSFORM_TEX(tex, name) (tex.xy *name##_ST.xy + name##_ST.zw)
//实现片元着色器，并在计算漫反射时使用纹理中的纹素值
fixed4 frag (v2f i) : SV_Target
{
fixed3 worldNormal = normalize(i.worldNormal);//首先计算世界空间下的法线方向和光照方向
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
//然后使用Cg的tex2D函数对纹理进行采样。它的第一个参数是需要被采样的纹理，第二参数是一个float2类型的纹理坐标，它将返回计算得到的纹素值。
//使用采样结果和颜色属性_Color的乘积来作为材质的反射率albedo,并把它和环境光照相乘得到环境光部分。
fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
//使用albedo来计算漫反射光照的结果，并和环境光照、高光反射光照相加后返回
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
fixed3 halfDir = normalize(worldLightDir + viewDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
return fixed4(ambient+diffuse + specular, 1.0);
}
ENDCG
}
}
Fallback "Specular" //为该Shader设置合适的Fallback
}
首先Properties属性部分，我们加入了_MainTex，可以在面板上设置，注意写法：
_MainTex ("Main Tex", 2D) = "white" {}
在Pass中，在声明变量那里，我们需要为纹理类型的属性声明一个float4类型的变量_MainTex_ST，首先，这个名字不是随便起的，在Unity中，我们要用纹理名_ST的方式来声明某个纹理的属性，ST是缩放（scale）和平移（translation）的缩写。_MainTex_ST可以让我们得到该纹理的缩放和平移（偏移）值。_MainTex_ST.xy存储的是缩放值，而_MainTex_ST.zw存储的是偏移值。这些值可以在材质面板的纹理属性中调节，如下图所示：
Tiling对应缩放，Offset对应偏移。
然后我们看看用到它的地方，在顶点着色器中，我注释掉了一行代码，先看看这行代码：
o.uv = v.uv.xy * _MainTex_ST.xy + _MainTex_ST.zw;
这是我们唯一用到_MainTex_ST的地方，从代码中看出，我们用_MainTex_ST的xy属性对顶点纹理坐标进行缩放，用zw进行偏移。而Unity提供了一个内置宏TRANSFORM_TEX来帮我们计算上述过程，我们看看它在UnityCG.cginc中的定义：
#define TRANSFORM_TEX(tex,name) (tex.xy * name##_ST.xy + name##_ST.zw)
第一个参数是纹理坐标，第二个参数是纹理名
代码完成后，在SingleTexMat的面板上，使用《UnityShader入门精要》书中第7章资源的Brick_Diffuse.jpg纹理对Main Tex属性进行赋值。显示效果图如下：