用Idea 2.4 生成对应数据库表的实体类和注解

1、打开View--Tool Windows--Database，如图：

2、选择数据库：

 

3、选择数据库后输入数据库对应的连接方式：

4、打开数据库找到对应是表：

5、找到生成的对应配置信息如下

6、新建文件名称：MyGenerate POJOs.groovy，然后加入如下配置保存：

import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

import java.text.SimpleDateFormat

/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */

packageName = "需要导出的包名自己根据项目填入对应的包名;"
typeMapping = [
        (~/(?i)int/)                      : "long",
        (~/(?i)float|double|decimal|real/): "double",
        (~/(?i)datetime|timestamp/)       : "java.sql.Timestamp",
        (~/(?i)date/)                     : "Date",
        (~/(?i)time/)                     : "Date",
        (~/(?i)/)                         : "String"
]

FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}

def generate(table, dir) {
    def className = javaName(table.getName(), true)
    def fields = calcFields(table)
    new File(dir, className + ".java").withPrintWriter { out -> generate(out, table.getName() ,className, fields) }
}

def generate(out, tabName ,className, fields) {
    out.println "package $packageName"
    out.println ""
    out.println ""
    out.println "import com.baomidou.mybatisplus.annotation.TableField;"
    out.println "import com.baomidou.mybatisplus.annotation.TableName;"
    out.println "import lombok.Data;"
    out.println "import java.io.Serializable;"
    out.println "import java.util.Date;"
    out.println ""
    out.println ""
    out.println "/**"
    out.println " * @author Generate"
    out.println " * @date ${new SimpleDateFormat('yyyy-MM-dd HH:mm:ss').format(new Date())}"
    out.println " */"
    out.println "@Data"
    out.println "@TableName(\"$tabName\")"
    out.println "public class $className implements Serializable{"
    out.println ""
    fields.each() {
        if (it.annos != "") out.println "  ${it.annos}"
        out.println "  @TableField(\"${it.colName}\")"
        out.println "  private ${it.type} ${it.name};"
    }
    out.println ""
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        fields += [[
                           name : javaName(col.getName(), false),
                           type : typeStr,
                           colName:col.getName(),
                           annos: ""]]
    }
}

def javaName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

7、然后在对应的表上右键，如图：

8、选择要生成的文件路径，最后生成实体