在 perl 中，如何使用变量值作为哈希元素

Question

我是 Perl 新手，在学习 Perl 书籍中找不到问题的答案。

例如我有一个数组：

my @loop=("op1_sel","op2_sel");

还有两个哈希表为：

my %op1_sel=(
       "bibuf","000",
       "self","101"
            );
my %op2_sel=(
        "zero","1",
        "temp","0"
            );

现在我想在循环中使用变量来循环获取特定键的哈希表 例如：

foreach(@loop)
{
     print  ${$_}{"bibuf"} ;
}

但它似乎不起作用，我知道${$_} 部分是错误的，谁能告诉我怎么做 解决这个问题？

Answer 1

使用嵌套哈希。像这样：

my %op;
# put a hash reference into hash, twice
$op{op1_sel} = \%op1_sel; 
$op{op2_sel} = \%op2_sel;

# later ...
foreach (keys %op) {
    print "bibuf of $_: $op{$_}->{bibuf}\n";
};

或者，长话短说，只是

my %op = (
    op1_sel => { 
        foo => 1,
        bar => 2,
        # ...
    },
    op2_sel => {
        # ...
    },
};

{} 构造创建对匿名哈希的引用，并且是处理嵌套数据结构的标准方法。

另见perldoc perldsc。

Answer 2

您不能使用 ${$foo} 语法来引用词法 (my) 变量。如果它们是包变量，您可能会使其工作，但这不是正确的方法。

正确的做法是使用嵌套数据结构。

我可以看到两种明显的方法。您可以直接创建一个包含内部哈希的 op_sel 数组，或者创建一个哈希哈希，然后对其进行索引。

所以“哈希数组”：

my @op_sels = (
    {
        bibuf => '000',
        self  => '101',
    },
    {
        zero => '1',
        temp => '0',
    },
);

for my $op (@op_sels) {
    print $$op{bibuf};
}

和“散列的散列”：

my %op_sels = (
    1 => {
       bibuf => '000',
       self  => '101',
    },
    2 => {
        zero => '1',
        temp => '0',
    },
);

for my $op_key (sort keys %op_sels) {
    print $op_sels{$op_key}{bibuf};
}

Answer 3

您可以为此使用 eval。

foreach(@loop)
{
      eval "\%var = \%$_";
      print $var{"bibuf"} ;
}