perl中如何给哈希赋值

Question

这是工作的一部分。在这一部分中，我正在尝试编写一个程序来创建哈希。键是文件中的登录号，值是整行。但是，该程序给了我一个警告。代码是：

#!/usr/bin/perl

#psuedocode:
#open file1, store uniport accesion as key and the line as value
#open file2, store uniport accesion as key and the line as value which lines contain "IDA"
#compare keys in two hashes, find out matched keys
#print out lines from file2 that match

use strict;
use warnings;
use feature qw(say);

my $infile1 = "geneIDs3_MouseToUniProtAccessions.txt";
my $inFH1;
open ($inFH1, "<", $infile1) or die join (" ", "Can't open", $infile1, "for reading:", $!);
my @array1 = <$inFH1>;
close $inFH1;
shift @array1;
my %geneID1;
for ($a = 0; $a < scalar @array1; $a++){
    chomp $array1[$a];
    $array1[$a] =~ /.*?\t(.*?)\t.*/;
    $geneID1{$1} = $array1[$a];
    #say ("$1", '->', "$geneID1{$array1[$a]}");    #test if the hash has been successfully created, however it doesn't
    #say $array1[$a];              #test if the program can recognize the elements, it does
}

文件geneIDs3_MouseToUniProtAccessions.txt 包含1,000 行，因此警告很多。前两行是：

From    To  Species Gene Name
PNMA3   Q9H0A4  Homo sapiens    paraneoplastic antigen MA3

警告如下：

Use of uninitialized value within %geneID1 in string at match_for_part_III_10.pl line 24.
Q9H0A4->

我找到了解决方案：改用 while 循环。它不仅有效，而且更优雅。新代码是：

 #!/usr/bin/perl

#psuedocode:
#open file1, store uniport accesion as key and the line as value
#open file2, store uniport accesion as key and the line as value which lines contain "IDA"
#compare keys in two hashes, find out matched keys
#print out lines from file2 that match

use strict;
use warnings;
use feature qw(say);

my $infile1 = "geneIDs3_MouseToUniProtAccessions.txt";
my $inFH1;
open ($inFH1, "<", $infile1) or die join (" ", "Can't open", $infile1, "for reading:", $!);
my %geneID1;

while (<$inFH1>){
    $_ =~ /.*?\t(.*?)\t.*/;
    $geneID1{$1} = $_;
    say ("$1", '->', "$geneID1{$1}");
}
close $inFH1;

感谢大家的大力帮助！

Answer 1

#!/usr/bin/perl

use strict;
use warnings;
use feature qw( say );

<>; # Skip header.

my %geneID1;
while (<>) {
   chomp;
   my @fields = split /\t/;
   my $id = $fields[1];
   $geneID1{$id} = $_;
}

say "$_ => $geneID1{$_}" for sort keys %geneID1;

（将geneIDs3_MouseToUniProtAccessions.txt 作为参数传递。）

Answer 2

很难用标签（它们是标签吗？）和更改问题中的代码来判断错误是什么。

但是，代码中有很多元素可以改进

use warnings;
use strict;
use feature 'say';

my $file = 'geneIDs3_MouseToUniProtAccessions.txt';
open my $fh, '<', $file or die "Can't open $file: $!";

my %geneID1;

my $header = <$fh>;    
while (<$fh>) {
    chomp;
    $geneID1{ (split /\t/)[1] } = $_; 
}

say "$_ => $geneID1{$_}" for sort keys %geneID1;

唯一的“通配符”是您的数据；如果您不确定TAB 字符，请使用\s+（也匹配制表符），因为您只需要第二个字段。通过split 默认值，您可以执行(split)[1]。

对原代码的注释

• 只有在有非常具体的原因时才提前读取文件

• 声明所有内容，即使某些特殊功能允许您不声明 ($a)

• 在尽可能小的范围内声明并靠近需要的地方：open my $fh, ...

• 不要使用像 $a 这样的特殊变量，除非它们的用途不同！

• 几乎不需要 C 风格的 for 循环。如果您在迭代中需要索引

  foreach my $i (0 .. $#ary) { ... }
  

  其中$#ary是数组@ary的最后一个元素的索引