如何设置 MojoX::Sessions 的 cookie 过期时间？答案

【问题标题】：How do I set the cookie expiration for MojoX::Sessions?如何设置 MojoX::Sessions 的 cookie 过期时间？
【发布时间】：2012-12-14 08:02:07
【问题描述】：

无论我给expires() 或expires_delta() 提供什么过期值，cookie 的过期时间总是一小时。如何更改它以使会话和 cookie 过期时间匹配？

【问题讨论】：

请向我们展示您遇到问题的实际代码。
$session->expires(time + 3600 * 8)

标签： perl session-cookies mojolicious mojolicious-lite

【解决方案1】：

虽然我喜欢 vti 的工作，但该发行版看起来已经过时并且在过去已被替换。今天在Mojolicious::Sessions 中解释了设置会话过期日期的标准方法：

default_expiration
my $time  = $sessions->default_expiration;
$sessions = $sessions->default_expiration(3600);
会话从现在开始过期的默认时间（以秒为单位），默认为 3600。每次请求都会刷新过期超时。将该值设置为 0 将允许会话持续到浏览器窗口已关闭，但这可能会产生安全隐患。更多控制您还可以使用expiration 和expires 会话值。
# Expiration date in epoch seconds from now (persists between requests)
$c->session(expiration => 604800);

# Expiration date as absolute epoch time (only valid for one request)
$c->session(expires => time + 604800);

# Delete whole session by setting an expiration date in the past
$c->session(expires => 1);

我写了一个小测试脚本来确保它可以工作：

#!/usr/bin/env perl

use Mojolicious::Lite;
use Time::Local 'timegm';

# set some session variable
get '/test' => sub {
    my $self = shift;
    $self->session(
        expires => timegm(0, 0, 0, 4, 4, 142), # star wars day '42
        foo     => 42,
    );
    $self->render_text('foo is set');
};

use Test::More;
use Test::Mojo;
use Mojo::Cookie::Response;
my $t = Test::Mojo->new;

$t->get_ok('/test')->status_is(200)->content_is('foo is set');
my $cookies = Mojo::Cookie::Response->parse($t->tx->res->headers->set_cookie);
is $cookies->[0]->expires, 'Sun, 04 May 2042 00:00:00 GMT', 'right expire time';

done_testing;

输出：

ok 1 - get /test
ok 2 - 200 OK
ok 3 - exact match for content
ok 4 - right expire time
1..4

【讨论】：