【问题标题】：Selecting a random key from a hash从哈希中选择随机密钥
【发布时间】：2018-02-24 22:09:34
【问题描述】：

如何选择随机哈希键？对于my Flash+Perl card game，我正在尝试从散列中选择一张随机牌，其中键为：“6 黑桃”、“6 梅花”等，如下所示：

my $card;
my $i = 0;
for $card (keys %{$user->{HAND}}) {
    last if rand(++$i) < 1;
}
delete $user->{HAND}->{$card};
print "random card: $card\n";

我想知道这是正确的方法还是有更好的方法。

【问题讨论】：

完全不正确。 for 循环中的 $card 是 "implicitly local to the loop and regains its former value upon exiting the loop"。也就是说，您的 print 语句中的 $card 与 for 循环中的 $card 是不同的变量。
此外，每次通过都会生成一个新数字这一事实会扭曲结果。

标签： perl

【解决方案1】：

更简洁一些：

my $random_value = $hash{(keys %hash)[rand keys %hash]};

【讨论】：

【解决方案2】：

从 %hash 中获取随机值

示例 sn-p：

my %hash = ( 
  'stack' => 'overflow',
  'face'  => 'book',
  'inter' => 'net'
);

## ALTERNATIVE 1 ##
my @hash_keys    = keys %hash;

my $random_key   = $hash_keys[rand @hash_keys];
my $random_value = $hash{$random_key};

## ALTERNATIVE 2 ##
my $random_val_2 = (%hash)[1+2*int rand keys%hash]; # TIMTOWTDI

## ALTERNATIVE 3 ##
my $random_val_3 = [@_=%hash]->[1|rand@_];          # TIMTOWTDI

【讨论】：

“1|”是什么意思在最后一行呢？
@AlexanderFarber 这是一个按位或，确保我们只在括号内得到奇数。 1 | 2 => 3、1 | 0 => 1、1 | 1 => 1。它总是将整数中的最低有效位设置为 1。
@refp ：我发现第一次调用它时总是返回相同的值：perl -Mstrict -wE 'my %hash = map { $_ => $_ } 1..100; say( (@_=%hash)[1|rand@_] ) for 1..10;'
@Zaid 哦，当然，感谢您的通知 - 查看我的编辑以查看 100% 工作示例。

【解决方案3】：

这是另一种方式（演示如何从未知长度的列表中选择随机元素）：

my $cards;
my $chosen;
while ( my $card = each %{$user->{HAND}} ) {
    $chosen = $card if rand(++$cards) < 1;
}

【讨论】：