为什么 pop/shift 在 perl 中不能与 map/grep 一起使用

Question

我想在map 和grep 操作之后获取第一个或最后一个元素 过阵列。将shift 和pop 运算符与map 和grep 一起使用 似乎不起作用。有什么建议么？如果我从map 保存结果，它会起作用 进入数组变量并弹出它，但我想在一行中做到这一点。

:$ cat map.pl 
use strict;
use warnings;
my @arr = (1,2,3,4);
my $ele = pop ( map{10* $_ } @arr ) ;
print "\n element is $ele";
:$ perl map.pl
Not an ARRAY reference at map.pl line 4.

Answer 1

map{10* $_ } @arr

产生一个列表，其元素是@arr 的对应元素乘以10。它不生成数组。因此，你不能pop 任何东西。您可以访问最后一个元素：

(map 10 * $_, @arr)[-1]

但是，地图不会改变@arr。如果你想这样做，

 $_ *= 10 for @arr;

比map更合适。

Answer 2

shift 和 pop 的第一个参数必须是数组（@NAME 或 @BLOCK），而不是 map 或 grep 运算符（与数组无关）。

您可以构建一个数组，从该数组到 shift/pop。

my $first_ele = shift @{ [ map { 10 * $_ } @arr ] };           # If you want first
my $last_ele  = pop   @{ [ map { 10 * $_ } @arr ] };           # If you want last

但这很浪费。您可以通过使用列表分配或列表切片来避免创建数组。

my ($first_ele) = map { 10 * $_ } @arr;                        # If you want first
my $first_ele = ( map { 10 * $_ } @arr )[0];                   # If you want first
my $last_ele  = ( map { 10 * $_ } @arr )[-1];                  # If you want last
my ($first_ele, $last_ele) = ( map { 10 * $_ } @arr )[0, -1];  # If you want both

但这仍然是浪费。当您只想要最后一个的乘积时，无需将所有元素相乘。以下更有意义：

my $first_ele = 10 * $arr[0];                                  # If you want first
my $last_ele  = 10 * $arr[-1];                                 # If you want last
my ($first_ele, $last_ele) = map { 10 * $_ } @arr[0, -1];      # If you want both

Answer 3

在列表上下文中，map 和 grep 生成列表，但 shift/unshift 和 push/pop 对数组进行操作。 Lists and arrays are not the same thing in Perl。您应该不太担心尝试在一行中完成所有操作，而应该更担心编写正确的代码。

Answer 4

第一个还是最后一个？首先你可以使用

    use strict;
    use warnings;
    my @arr = (1,2,3,4);
    my ($ele) = map{10* $_ } @arr;
    print "\n element is $ele\n\n";