将 Perl 的“特定声明”作为变量

Question

如果可能的话，如果以下设置可以解释为变量的正式声明，我正在寻找某种解决方案。 我所拥有的是：

my $str_1 = "{cow}" ;

my $str_2 = "{cow}{black}{tasty_milk}";

我想要的是：

(基于上面的变量字符串是否可以直接初始化哈希， 类似:)

my %hash=();

$hash."*some operator* on $str_i"  = 'Initialized' ;

这个“一些运算符”应该使 $hash 能够识别为之前声明的哈希值。即输入特定的哈希初始化。

PS：我不想编写一个函数来处理字符串并获取所有信息来初始化哈希。

Answer 1

假设您有以下输入：

my @path = qw( cow black tasty_milk );

然后你可以使用以下内容：

use Data::Diver qw( DiveVal );

DiveVal(\%hash, map \$_, @path) = 'value';

所以，使用Data::Diver，我们得到：

use Data::Diver qw( DiveVal );

$str =~ /^(?:\{\w+\})+\z/
   or die("Unrecognized format");

my @path = $str =~ /(\w+)/g;
DiveVal(\%hash, map \$_, @path) = 'value';

没有模块：

sub dive_val :lvalue { my $p = \shift;  $p = \( $$p->{$_} ) for @_;  $$p }

$str =~ /^(?:\{\w+\})+\z/
   or die("Unrecognized format");

my @path = $str =~ /(\w+)/g;
dive_val(\%hash, @path) = 'value';

Answer 2

使用匿名哈希尝试以下操作

use Data::Dumper;
use warnings; 
use strict;

my $str_2 = "{cow}{black}{tasty_milk}";
my %hash;
my $ref =\%hash;
my $val;
my $lp = () = $str_2=~m/\}/g; #count the number of }
my $i = 1;
while($str_2=~m/\{(\w+)\}/g)
{
    $val = $1;

    last if ($lp == $i); 

    $ref->{$val} = {}; #make the anonymous hash        

    $ref = $ref->{$val};   #add the data into anonymous hash

    $i++;

}
$ref->{$val} = "value"; #add the last value

print Dumper \%hash;