【问题标题】:subtracting values in one column based on another column根据另一列减去一列中的值
【发布时间】:2016-12-30 03:22:43
【问题描述】:

我的输入文件如下

100A 2000
100B 150
100C 800
100A 1000
100B 100
100C 300

我想为第 1 列中的每个 uniq 值减去第 2 列中的值 所以输出应该看起来像

100A 1000
100B 50
100C 500

我试过了

 awk '{if(!a[$1])a[$1]=$2; else a[$1]=$2-a[$1]}END{ for(i in a)print i" " a[i]}' file 

但输出是:

100A 0
100B 0
100C 0

请指教

【问题讨论】:

  • 如果第一列中的值重复多次会怎样?
  • 在这种情况下,我想取第一次和最后一次出现
  • 所有发布的解决方案都不会这样做,他们所做的只是适用于您提供的 2 条目示例(除我之外的所有示例都不必要地将一半输入保存在数组中,然后以随机顺序生成输出而不是严格按照读取键值的顺序(可能需要也可能不需要)。
  • @EdMorton:您的解决方案对我有用,但我有一个查询已在您解决方案的评论部分发布
  • @user3369871 - 正如 Ed 所说,您对现有解决方案的 >2 个样本(包括他的)不走运。我刚刚更新了我的以处理您的第一次/最后一次出现条件,并提供了一种控制顺序的机制。

标签: awk


【解决方案1】:

同一个主题有这么多(轻微的)变化。

awk '
  !($1 in a) {a[$1]=$2; next}
  {a[$1]-=$2}
  END {for (i in a) printf "%s %d\n",i,a[i]}
' input.txt

如果你愿意,可以把它叠成一条线。

请记住,awk 结构由多个 condition { statement } 对组成,因此您有时可以比使用 if..else 更优雅地表达您的需求。 (并不是说这里就是这种情况 - 这是一个足够简单的 awk 脚本,它可能无关紧要,除非你是一个纯粹主义者。:])

另外,请注意您在问题中if 的条件下测试值的方式。请注意,a[$1] both 测试该数组索引处的值是否非零 并且 会导致索引以空值存在(如果它以前不存在)。如果要检查索引是否存在,请使用$1 in a。


根据对您问题的评论进行更新...

如果你想从 first 条目中减去 last,忽略中间的那些,那么你需要记录你的第一个和你的最后一个。这样的事情可能就足够了。

awk '
  !($1 in a){a[$1]=$2;next}
  {b[$1]=$2}
  END {for(i in b)if(i in a)print i,a[i]-b[i]}
' input.txt

请注意,正如 Ed 所提到的,这会以随机顺序产生输出。如果您希望输出排序,则需要一个额外的数组来跟踪顺序。例如,这将使用首先看到项目的顺序:

awk '
  !($1 in a) {
    a[$1]=$2;
    o[++n]=$1;
    next
  }
  {
    b[$1]=$2
  }
  END {
    for (n=1;n<=length(o);n++)
      print o[n],a[o[n]]-b[o[n]]
  }
' i

请注意,用于确定数组中元素数量的 length() 函数在 awk 方言中并不通用,但它在 gawk 和 one-true-awk(用于 FreeBSD 和其他)中都有效。

【讨论】:

  • 我同意,但是当索引不存在时我分配了一个值 a[$1]=$2 那么我的解决方案有什么问题?
  • 您的测试是if(!a[$1]),它不会测试不存在,它会导致索引存在(如果它不存在)并测试值为零。我不确定你为什么会得到你在问题中提到的结果,但你的减法倒退了。你从第一个值中减去第二个值,所以当我运行你的示例代码时,我看到负数(1000 - 2000、100 - 150、300 - 800)。
  • 它们可能是负数,因为我必须找到整数差,我刚刚意识到我的解决方案也在工作,我的解决方案没有任何问题我只是使用错误的输入文件运行它跨度>
  • 不,您的解决方案有问题,当遇到的第一个 $2 值为零时,它会失败。请参阅@ghoti 的评论了解原因。
  • 仅供参考,长度(数组)现在是 POSIX,因此这些天通常被认为是可移植的。您可以改用for (n=1;n in o;n++) 来保证对所有awk 的可移植性,并且您不需要测试o[n] in a,因为它是不可能的。
【解决方案2】:

这个 awk 单行代码可以完成这项工作:

 awk '{if($1 in a)a[$1]=a[$1]-$2;else a[$1]=$2}
      END{for(x in a) print x, a[x]}' file

【讨论】:

  • 使用 if/else 而不是 awk 为 condition { statement } 构造提供的隐式结构有什么好处吗?
【解决方案3】:

在 awk 中。使用条件运算符进行值放置/减法以保持紧密:

$ awk '{ a[$1]+=($1 in a?-$2:$2) } END{ for(i in a)print i, a[i] }' file
100A 1000
100B 50
100C 500

解释:

{ 
    a[$1]+=($1 in a?-$2:$2)  # if $1 in a already, subtract from it 
                                # otherwise add value to it
} 
END { 
    for(i in a)              # go thru all a
        print i, a[i]          # and print keys and values
}

【讨论】:

    【解决方案4】:

    鉴于您提供的示例输入,您只需要:

    $ awk '$1 in a{print $1, a[$1]-$2} {a[$1]=$2}' file
    100A 1000
    100B 50
    100C 500
    

    如果这还不是您所需要的,那么提供更具代表性的示例输入/输出,包括不够好的情况。

    【讨论】:

    • 感谢 Ed 有效,这是在 awk 的条件块中实现 if -else 的一种方法,当 a 中的 $1 评估为 true 并且 {a [$1]=$2} 充当 else 并在 a 中的 $1 评估为 false 时执行?
    • 不,否则你会在第一个 } 之前插入 ;next。现在,每一行都会发生分配,只是在功能上发生这种情况并不重要。
    【解决方案5】:

    你可以使用这个awk:

    awk 'a[$1]{a[$1]=a[$1]-$2; next} {a[$1]=$2} END{for(v in a){print v, a[v]}}' file
    

    【讨论】:

      猜你喜欢
      • 1970-01-01
      • 2021-02-22
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      • 2018-10-12
      • 2021-09-10
      • 2019-04-12
      相关资源
      最近更新 更多