使用带有 utf 编码文件的 perl tie::file

Question

我可以将Tie::File 与utf 编码的输出文件一起使用吗？我无法让它正常工作。 我要做的是打开这个 utf 编码文件，从文件中删除匹配字符串并重命名文件。

代码：

use strict;
use warnings;
use Tie::File;
use File::Copy;

my ($input_file) = qw (test.txt);

open my $infh, "<:encoding(UTF-16LE)", $input_file or die "cannot open '$input_file': $!";

for (<$infh>) {
    tie my @lines, "Tie::File", $_;
    shift @lines if $lines[0] =~ m/MyHeader/;
    untie @lines;
    my ($name) = /^(.*).csv/i;
    move($_, $name . ".dat");
}

close $infh
    or die "Cannot close '$input_file': $!";

代码：（更新）

my ($input_file) = qw (test.txt);
my $qfn_in = $input_file;
my $qfn_out = $qfn_in . ".dat";

open(my $fh_in, "<:raw:perlio:encoding(UTF-16le):crlf:utf8", $qfn_in)
   or die("Can't open \"$qfn_in\": $!\n");

open(my $fh_out, ">:raw:perlio:encoding(UTF-16le):crlf:utf8", $qfn_out)
   or die("Can't open \"$qfn_out\": $!\n");

while (<$fh_in>) {
   next if $. == 1 && /MyHeader/; 
   print($fh_out $_)
      or die("Can't write to \"$qfn_out\": $!");
}

close($fh_in);
close($fh_out) or die("Can't write to \"$qfn_out\": $!");

rename($qfn_out, $qfn_in)
   or die("Can't rename: $!\n");

Answer 1

这在Tie::File perldoc 中没有记录，但您想在绑定文件时传递discipline => ':encoding(UTF-16LE)' 选项：

tie my @lines, 'Tie::File', $input_file, discipline => ':encoding(UTF-16LE)'

请注意，第三个参数是与绑定数组关联的文件的名称。 Tie::File会自动为你打开和管理文件句柄；无需自己在文件上调用open。

@lines 现在包含文件的内容，所以接下来要做的是检查第一行：

if ($lines[0] =~ m/pattern/) {
    my $line = shift @lines;
    untie @lines;   # rewrites, closes the file, w/o first line
    my ($name) = $line =~ /^(.*).csv/i;
    rename $input_file, "$name.dat";
}

但我同意 TLP 的观点，即 Tie::File 对于这份工作来说太过分了。

（我之前关于使用正确编码打开文件句柄并将 glob 作为第三个参数传递给 Tie::File 的回答不起作用，因为（1）它没有以读/写模式打开文件并且（ 2) 即使这样做了，Tie::File 也不能或不对文件句柄的读取和写入应用编码）

Answer 2

my $qfn_in = ...;
my $qfn_out = $qfn_in . ".tmp";

open(my $fh_in, "<:raw:perlio:encoding(UTF-16le):crlf:utf8", $qfn_in)
   or die("Can't open \"$qfn_in\": $!\n");

open(my $fh_out, ">:raw:perlio:encoding(UTF-16le):crlf:utf8", $qfn_out)
   or die("Can't open \"$qfn_out\": $!\n");

while (<$fh_in>) {
   next if $. == 1 && /MyHeader/;
   print($fh_out $_)
      or die("Can't write to \"$qfn_out\": $!");
}

close($fh_in);
close($fh_out) or die("Can't write to \"$qfn_out\": $!");

rename($qfn_out, $qfn_in)
   or die("Can't rename: $!\n");

（:perlio 和 :utf8 是针对当时存在的错误的解决方法。）

Answer 3

行：

tie my @lines, "Tie::File", $_;

尝试将@lines 绑定到每行名称为test.txt 的文件。由于它似乎不是包含文件名的文件，我怀疑 tie 失败。

您可能想要在test.txt 上使用Tie::File。如果您只想检查该文件的第一行，则不需要循环。

所以你需要这样的东西：

use autodie;  #handy to check for fatal errors
tie my @lines, "Tie::File", $input_file;
shift @lines if $lines[0] =~ /MyHeader/;
untie @lines;
if ($input_file =~ /(.+).csv/i) {
    move($input_file, $1);
}

但是有更简单的方法可以检查文件的第一行。这将检查一个文件：

perl -we '$_=<>; print if /MyHeader/; print <>;' test.txt > test.dat