当某个阶段中止时，如何标记构建成功？

Question

我有一个带有阶段的管道，其中一个阶段间歇性地花费比预期更长的时间，因此使用timeout 中止它。但是如果阶段被中止，构建也被标记为中止。以下是管道的代码：

pipeline {
    agent any

    stages {

        stage('First') {
            options {
                timeout(time: 10, unit: 'SECONDS')
            }
            steps {
                script {

                    catchError(buildResult: 'SUCCESS') {
                        echo "Executing stage I"
                        sleep 12
                    }

                }
            }
        }

        stage('Second') {
            steps {
                script {
                    echo "Executing stage II"
                }
            }
        }
    }
}

即使阶段标记为Aborted，我也想将构建标记为Success。你能帮助我如何实现这一目标吗？

Answer 1

我建议对迈克尔的答案进行一项改进（顺便说一句，这是正确的）。您可以使用catchError 标记阶段ABORTED（或UNSTABLE）并标记构建SUCCESS，但您需要使用try-catch 块包装可能超时的代码以控制错误。考虑以下示例：

pipeline {
    agent any

    stages {

        stage('First') {
            options {
                timeout(time: 3, unit: 'SECONDS')
            }
            steps {
                script {
                    catchError(buildResult: 'SUCCESS', stageResult: 'ABORTED') {
                        try {
                            echo "Executing stage I"
                            sleep 4
                        } catch(org.jenkinsci.plugins.workflow.steps.FlowInterruptedException e) {
                            error "Stage interrupted with ${e.toString()}"
                        }
                    }

                }
            }
        }

        stage('Second') {
            steps {
                script {
                    echo "Executing stage II"
                }
            }
        }
    }
}

当你运行这个流水线时，超时的阶段被标记为ABORTED，但流水线继续，如果剩余阶段没有失败，它被标记为SUCCESS。

这就是UNSTABLE 阶段状态的样子。

Michael 的解决方案同样有效，但产生的结果略有不同 - 超时的阶段标记为 SUCCESS，这可能不太直观。你需要点击舞台来检查它是否超时。

pipeline {
    agent any

    stages {

        stage('First') {
            options {
                timeout(time: 3, unit: 'SECONDS')
            }
            steps {
                script {
                    try {
                        echo "Executing stage I"
                        sleep 4
                    } catch(Exception e) {
                        currentBuild.result = "SUCCESS"
                    }
                }
            }
        }

        stage('Second') {
            steps {
                script {
                    echo "Executing stage II"
                }
            }
        }
    }
}

Answer 2

您的catchError() 不适用于您的情况。文档 (Source) 说明以下内容：

buildResult（可选）

如果发现错误，则整体构建结果 将设置为此值。 注意构建结果只能得到 更糟糕的是，如果当前的 结果是 UNSTABLE 或更糟。 使用 SUCCESS 或 null 来保持构建 捕获错误时设置的结果。

使用currentBuild.currentResult 设置构建状态，它可以有三个值：SUCCESS、UNSTABLE 或FAILURE。

如果您想在中止时将构建标记为 SUCCESS，则可以使用后选项 (Source) aborted：

pipeline {
    agent any
    stages {
        stage('Example') {
            steps {
                echo 'Hello World'
            }
        }
    }
    post { 
        aborted { 
            // Executed only if stage is aborted
            currentBuild.result = 'SUCCESS'
        }
    }
}