在处理 3 中需要子弹与敌人互动的帮助答案

【问题标题】：Need assistance with bullet to enemy interaction in Processing 3在处理 3 中需要子弹与敌人互动的帮助
【发布时间】：2015-11-19 07:32:32
【问题描述】：

我正在为我的编程课编写游戏。这是一款以其他飞机为“敌人”的飞机射击游戏。射击的飞机会射出小椭圆。我无法弄清楚如何将被击中的敌人从游戏中移除。我知道如何消除“敌人”，但不知道如何在它们发生碰撞时做到这一点。这是我当前的代码。

    ArrayList <Bullet> bullets = new ArrayList <Bullet> ();
    ArrayList enemies;
    PVector player, playerSpeed;
    float maxSpeed = 3;
    PImage jet;
    PImage enemy;
    PImage laser;
    void setup() {
      size(600, 600);
      player = new PVector(300, 550);
      playerSpeed = new PVector();
      noCursor();
      noStroke();
      smooth();
      String jeturl = "http://s1.postimg.org/dhe38w1rv/fighter_jet_md_20.png";
      String enemyurl =                "http://s29.postimg.org/cdaj0d7z7/fighter_jet_md_20.png";
      String laserurl = "http://s13.postimg.org/fq00vsl37/red_Laser_Ray.png";
      // Load image from a web server
      jet = loadImage(jeturl, "png");
      enemy = loadImage(enemyurl, "png");
      laser = loadImage(laserurl, "png");
      enemies = new ArrayList();
    }

    void draw() {
      background(255);

      player.add(playerSpeed);
      //fill(255, 0, 0);
      image(jet, player.x, player.y);

      PVector mouse = new PVector(mouseX, mouseY);
              fill(10);
      ellipse(mouse.x, mouse.y, 5, 5);

      if (frameCount%7==0 && mousePressed) {
        PVector dir = PVector.sub(mouse, player);
        dir.normalize();
        dir.mult(maxSpeed*3);
        Bullet b = new Bullet(player, dir);
        bullets.add(b);
      }
     for(int i = enemies.size()-1; i>=0; i--) {
        Enemy b = (Enemy) enemies.get(i);
        b.move();
        b.draw();



      }

      if (frameCount%50==0) {
        enemies.add(new Enemy());


      }

      for (Bullet b : bullets) {
        b.update();
        b.display();
      }




    }

    class Bullet extends PVector {
      PVector vel;

      Bullet(PVector loc, PVector vel) {
        super(loc.x, loc.y);
        this.vel = vel.get();
      }

      void update() {
        add(vel);
      }

      void display() {
        fill(0, 0, 255);
        ellipse(x, y, 3, 3);
      }
    }

    class Enemy {
      float x, y;
      Enemy() {
            x = random(20, 580);
            y = random(-20, -580);

      }

      void move() {
        y = y + random(1,3);

      }

      void draw() {
        image(enemy, x, y);

      }
    }

    void keyPressed() {

      if (keyCode == LEFT)  { 

      playerSpeed.x = -maxSpeed; 

       }
      if (keyCode == RIGHT) { 

      playerSpeed.x = maxSpeed;

       }
    }

    void keyReleased() {

      if (keyCode == LEFT || keyCode == RIGHT) { 
      playerSpeed.x = 0; 
    }
    }

【问题讨论】：

您的命中检测代码在哪里？
@willywonka_dailyblah 它不存在

标签： processing collision-detection collision detection

【解决方案1】：

你知道子弹和敌人的坐标，因此你可以检查碰撞。有一个内置的dist() 函数可以计算两点之间的欧几里得距离。

虽然效率不高，也不准确，但您可以这样做：

ArrayList <Bullet> bullets = new ArrayList <Bullet> ();
ArrayList enemies;
PVector player, playerSpeed;
float maxSpeed = 3;

PImage jet;
PImage enemy;
PImage laser;

int lives = 3;
int score = 0;

void setup() {
  size(600, 600);
  player = new PVector(300, 550);
  playerSpeed = new PVector();
  noCursor();
  noStroke();
  smooth();
  String jeturl = "http://s1.postimg.org/dhe38w1rv/fighter_jet_md_20.png";
  String enemyurl = "http://s29.postimg.org/cdaj0d7z7/fighter_jet_md_20.png";
  String laserurl = "http://s13.postimg.org/fq00vsl37/red_Laser_Ray.png";
  // Load image from a web server
  jet = loadImage(jeturl, "png");
  enemy = loadImage(enemyurl, "png");
  laser = loadImage(laserurl, "png");
  enemies = new ArrayList();


}

void draw() {
  background(255);

  player.add(playerSpeed);
  //fill(255, 0, 0);
  image(jet, player.x, player.y);

  PVector mouse = new PVector(mouseX, mouseY);
  fill(10);
  ellipse(mouse.x, mouse.y, 5, 5);

  if (frameCount%7==0 && mousePressed) {
    PVector dir = PVector.sub(mouse, player);
    dir.normalize();
    dir.mult(maxSpeed*3);
    Bullet b = new Bullet(player, dir);
    bullets.add(b);
  }
  for (int i = enemies.size ()-1; i>=0; i--) {
    Enemy b = (Enemy) enemies.get(i);
    b.move();
    b.draw();
    //check enemy to bullet collisions
    //for each bullet
    for(Bullet blt : bullets) {
      //if the distance between the bullet and enemy is less than the enemy's width
      if(dist(blt.x,blt.y,b.x,b.y) < enemy.width){
        //remove the enemy
        enemies.remove(b);
        //optional, add score
        score += 10;
      }
    }
    //check enemy to player collision
    if(dist(player.x,player.y,b.x,b.y) < jet.width){
      enemies.remove(b);//remove current enely

      //optional, update lives, reset score/game if needed
      lives--;
      println("player hit: " + lives + " lives left");

      if(lives < 1){
        println("Game Over!\nscore:" + score);
        lives = 3;
        score = 0;
      }

    }
  }

  if (frameCount%50==0) {
    enemies.add(new Enemy());
  }

  for (Bullet b : bullets) {
    b.update();
    b.display();
  }
}

class Bullet extends PVector {
  PVector vel;

  Bullet(PVector loc, PVector vel) {
    super(loc.x, loc.y);
    this.vel = vel.get();
  }

  void update() {
    add(vel);
  }

  void display() {
    fill(0, 0, 255);
    ellipse(x, y, 3, 3);
  }
}

class Enemy {
  float x,y;

  Enemy() {
    x = random(20, 580);
    y = random(-20, -580);
  }

  void move() {
    y = y + random(1, 3);
  }

  void draw() {
    image(enemy, x, y);
  }
}

void keyPressed() {

  if (keyCode == LEFT) { 

    playerSpeed.x = -maxSpeed;
  }
  if (keyCode == RIGHT) { 

    playerSpeed.x = maxSpeed;
  }
}

void keyReleased() {

  if (keyCode == LEFT || keyCode == RIGHT) { 
    playerSpeed.x = 0;
  }
}

上述代码不准确的原因是它根据距离检查碰撞。想象一个围绕已检查对象的圆圈。如果您的对象是圆形，这将是完美的，但您大多是矩形 (PImages)。

上述代码运行缓慢的原因与 dist() 函数的工作方式有关。想象屏幕上两个对象之间的一条线。从一个对象到另一个对象绘制两条直线，并限制为水平和垂直，这将为您提供直角三角形的两侧，其中连接对象的原始线是斜边。要找到距离，您将求解hypothenuse，它是两侧相加的平方根。您不必为此担心太多，因为 dist() 会为您完成此数学运算，但请记住，它使用平方根，这在 CPU 上的成本可能很高。解决此问题的一种方法是使用平方距离（并检查半径平方），但这不会太准确。

另一种选择是进行简单的矩形边界检查。您知道每个框 (PImage) 在屏幕上的位置以及每个子弹的绘制位置，因此如果每个子弹都在敌人体内，您就可以进行锻炼。同样，您可以检查两个矩形是否相交（玩家 PImage 和敌人 PImage 的坐标已更新）。

这是一个矩形相交的最小示例，利用 java.awt.Rectangle 类（它已经提供了对相交的检查）：

import java.awt.Rectangle;

//based on jet image from previous code
int jetWidth = 20;
int jetHeight = 28;

Rectangle playerBox,enemyBox;

void setup(){
  size(600, 600);
  noFill();strokeWeight(3);
  //bounding boxes
  playerBox = new Rectangle(width / 2, height-jetHeight*2,jetWidth,jetHeight);
  enemyBox = new Rectangle((int)random(width),-jetHeight,jetWidth,jetHeight);
}

void draw(){
  //update enemy
  enemyBox.y += 3;
  //reset enemy position if out of screen
  if(enemyBox.y > height) {
    enemyBox.y = -jetHeight;
  }
  playerBox.x = (int)(mouseX - jetWidth * .5);

  //check collision
  if(playerBox.intersects(enemyBox)){
    strokeWeight(10);
  }else{
    strokeWeight(3);
  }

  background(255);
  stroke(192,0,0);
  rect(enemyBox.x,enemyBox.y,enemyBox.width,enemyBox.height);
  stroke(0,192,0);
  rect(playerBox.x,playerBox.y,playerBox.width,playerBox.height);
}

如果您想要像素精度，您可以利用您加载的图像的 Alpha 通道，并且：

最初做边界框测试
如果（且仅当）绑定框相交，循环遍历一个图像的非透明像素以检查另一张图像的非透明像素）。（如果您知道物体的方向，则可以使用它开始计算最接近可能碰撞的像素）

作为下一步，我建议实施基于边界框的碰撞检测。稍后您可能想查看基本的state machines 以跟踪游戏的状态（例如介绍屏幕、级别 1、级别 2、...、游戏结束屏幕、高分屏幕等）

玩得开心！ :)

【讨论】：

这绝对是完美的。我是 9 年级的 pgm 入门，所以我怀疑我的老师会对我有这么多的期望。我肯定会研究状态机，因为关卡是项目的一部分。太感谢了。感恩节快乐！！
很高兴听到这个消息。我已经更新了答案以包含一个基本的矩形相交示例。如果有帮助，请随意投票/标记答案；）

【解决方案2】：

你需要为你的敌人类添加一个监听器。它应该是项目符号列表的无限循环。并且它应该具有在子弹坐标等于敌人坐标时执行 on_delete 回调的逻辑。我不是 Java 开发人员，但我会为您编写一些伪代码，这些伪代码应该可以为您指明正确的方向。需要做一个小改动，Enemy 类需要使用敌人数组上的元素索引进行初始化，以便可以通过回调正确销毁它。

Class Enemy (int idx){
    void on_delete(){
         enemies = ArrayUtils.removeElement(idx)};
    void listen(){
    cycle{ 
           for(i=0; bullets.count()-1;i++){
           bullet_x = bullets(i).getX
           bullet_y = bullets(i).getY
           if (bullet_x==x) && (bullet_y==y)
           on_delete();
           }
       } 
}

【讨论】：