错误数据类型的公式中使用的值

Question

过去几天我一直在尝试解决这个错误，但没有成功。我希望你们中的一个能够提供帮助。我得到“在错误数据类型的公式中使用的值。

快速解释： 将这样的函数转换为相应的文本 (20054/18393)*100.0 5 位数字是指问题的字段 ID。

身份证问题 20054 你一年工作多少天 18393 一年有多少天的假期

我想要得到的结果是（你一年中有多少天工作/你一年有多少天假期）*100.0 如果只是一只手，它可以很容易地手动完成。我有超过 2600 个公式需要转换。 我在下面创建了这个函数，这导致了标题中提到的错误。任何帮助将不胜感激

这是我的功能

Function Test(sInput As String) As String
Dim i As Long
Dim num As String
Dim Text, a, str, shortname As String

For i = 1 To Len(sInput)
    a = Mid(sInput, i, 1)
    If IsNumeric(a) Then
        num = num & a
        Text = ""
    Else
        If a = "." Then
            num = num & a
        Else
            'search for num value in second sheet short name
            shortname = WorksheetFunction.VLookup(WorksheetFunction.Int(num), Worksheets("questionlist").Range("A3:F2537"), 5, False)
            num = ""
        End If

        Text = shortname & a
        shortname = ""
    End If
    str = str & Text
Next

Test = str
End Function

Answer 1

引发错误是因为您在行中将空白值传递给INT Function

 WorksheetFunction.VLookup(WorksheetFunction.Int(num), Worksheets("questionlist").Range("A3:F2537"), 5, False)

重现错误 在任何单元格中键入=INT("")

修复这个句柄空白值

更新答案：

Function Formula2Text(ByRef myCell As Range) As String
Dim QuestionId As Integer
Dim strInput As String

'Get Formula instead of values
strInput = myCell.FormulaR1C1

'Use Regex to Catch all ID's
 Set Regex = CreateObject("VBScript.RegExp")
 Set rnglookup = Worksheets("questionlist").Range("A3:F2537")
  Regex.Global = True
  Regex.Pattern = "\d+"     

For Each Match In Regex.Execute(strInput)

    'Skip if the ID is 100
    If (Match.Value <> 100) Then QuestionId = Match.Value

    'Lookup ID in the rnglookup,Make sure the Ids are sorted in asc in the questionlist sheet
    Qntxt = Application.VLookup(QuestionId, rnglookup, 5, False)

    If IsError(Qntxt) Then Qntxt = "Missing Lookup"

   'Replace the ID with the lookup
    strInput = Replace(strInput, QuestionId, Qntxt)

Next
Formula2Text = strInput

End Function

用法：在公式旁边的单元格中，通过引用公式来使用函数

 =Formula2Text(A1)