需要遍历和修改 Excel 工作表中的单元格...我从哪里开始？

Question

我在做什么

我需要修改一个文件（从 salesforce 导出），其中行具有唯一 ID、名称和具有此表中另一行的唯一 ID 的列，将其标识为该项目的“子项”。

1. ID（columnA）
2. 名称（列 B）
3. 父 ID（columnC）

未受影响数据的图像：

我需要完成什么

我的目标是遍历整个电子表格（55,000 行）并将 ParentID 更改为父名称列中的值。

我的伪代码解决方案

foreach row starting from the top {
    varA = [current row number for this loop];
    varX = [value in varA:columnC];
    if (varX == [regex value]) {
        foreach row starting from the top {
            varB = [current row number for this loop];
            if ([value in varB:columnA] == varX) {              
                foreach row starting from the top {
                    varC = [current row number for this loop];
                    if (varC:columnC = varB:columnA) {
                        [varC:columnC] = [varB:columnB];
                    }
                }
                break second foreach loop;
            }
        }
    }
}

手动修复后的数据图：

到目前为止我所做的研究

我正在使用 excel，我找到了讨论如何创建新宏的资源，其中一些甚至有示例，但我不确定这是否是合适的地方。我还有一个朋友建议使用 Pandas 修改文件会更好，但我也不熟悉。

我的问题：

我从哪里开始？ ...编写脚本来修改所有这些的正确工具是什么？

另外，如果可能的话，您能否推荐一个资源供我在使用合适的工具完成这项工作时作为参考？

Answer 1

改变这个，

.. 使用此代码，

Option Explicit

Sub wqweqrteq()
    Dim d As Long, dict As Object, vals As Variant

    Set dict = CreateObject("Scripting.Dictionary")

    With Worksheets("salesforce")
        With .Range(.Cells(2, "A"), .Cells(.Rows.Count, "C").End(xlUp))
            vals = .Value2
        End With

        For d = LBound(vals, 1) To UBound(vals, 1)
            dict.Item(vals(d, 1)) = vals(d, 2)
        Next d

        For d = LBound(vals, 1) To UBound(vals, 1)
            If dict.exists(vals(d, 3)) Then
                vals(d, 3) = dict.Item(vals(d, 3))
            End If
        Next d

        With .Range(.Cells(2, "A"), .Cells(.Rows.Count, "C").End(xlUp))
            .Value = vals
        End With
    End With

End Sub

.. 进入这个。

Answer 2

以下 For 循环 可以解决您的问题：

Sub UpdateID()

Dim lastrow As Long
Dim x As Long, y As Long, z As Long
Dim ParentName As String

lastrow = Cells(Rows.Count, "A").End(xlUp).Row

For x = 2 To lastrow
    If Left(Cells(x, 3), 2) = 0 Then
        For y = 2 To lastrow
            If Cells(x, 3).Value = Cells(y, 1).Value Then
            ParentName = Cells(y, 2).Value
            Exit For
            End If
        Next y
    End If

    For z = 2 To lastrow
        If Cells(z, 3).Value <> "" And Cells(x, 3).Value = Cells(z, 3).Value Then
        Cells(z, 3).Value = ParentName
        End If
    Next z
Next x

End Sub