每个工作表的重复任务，根据单元格值取消隐藏和隐藏

Question

我有这个当前的代码工作，但是我想对工作表中的很多行和工作簿中的其他工作表重复相同的任务。

我想重复的任务是根据是/否下拉菜单取消隐藏和隐藏行。我知道可以在模块中创建代码并在每张表中调用它。将不胜感激。

谢谢！！

Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
    If Intersect(Target, Range("C6")) Is Nothing Then Exit Sub
    If Target = "Yes" Then
        Rows("7:7").Hidden = False
    ElseIf Target = "No" Then
        Rows("7:7").Hidden = True
    End If
End Sub

Answer 1

可能是这样的，使用Workbook.SheetChange event。将此代码添加到ThisWorkbook 代码模块。它假定除了您的下拉列表之外没有其他单元格说“是”或“否”。如果不是这种情况，它可以很容易地修改。如果需要，也可以将其修改为仅处理某些工作表并排除其他工作表。

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    If Target.CountLarge > 1 Then Exit Sub
    Select Case Target.Value
        Case "Yes"
            Target.Offset(1).EntireRow.Hidden = True
        Case "No"
            Target.Offset(1).EntireRow.Hidden = False
    End Select
End Sub

正如answer 到您之前的@​​987654323@ 中所述，您可以使用LCase 使此不区分大小写：

Select Case LCase(Target.Value)
    Case "yes"
        ....
    Case "no"
        ....
End Select

编辑：

修改为根据名称排除某些工作表：

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    If Target.CountLarge > 1 Then Exit Sub

    Select Case Sh.Name
        Case "Sheet2", "Sheet4" ' change to the names of the sheets to exclude
            Exit Sub
    End Select

    If VarType(Target.Value) = vbString Then
        Select Case LCase(Target.Value)
            Case "yes"
                Target.Offset(1).EntireRow.Hidden = True
            Case "no"
                Target.Offset(1).EntireRow.Hidden = False
        End Select
    End If
End Sub