Power Query：检测由 Table.NestedJoin JoinKind.FullOuter 创建的 null

Question

使用Table.NestedJoin JoinKind.FullOuter，当右表“key”中存在左表“key”中不存在的值时，可以将null写入列。

但是，与左表中的 null 不同，因为单元格为空，此创建的 null 不 = True 与公式 [column] = null。

例如：

Table1
注意第 3 行中的空值

Table2

联接表
第 5 行中的空值是联接的结果

自定义列
添加了公式 =[A]=null
注意 null 的不同结果
@987654324 @

MCode 重现上述

let
    Source1 = Table.FromRecords({
        [A="a"],
        [A="b"],
        [A=null],
        [A="c"]
    }),
    type1 = Table.TransformColumnTypes(Source1,{"A", type text}),
    Source2 = Table.FromRecords({
        [A="c"],
        [A="d"]
    }),
    type2 = Table.TransformColumnTypes(Source2,{"A", type text}),

    combo = Table.NestedJoin(type1,"A",type2,"A","joined",JoinKind.FullOuter),
    #"Added Custom" = Table.AddColumn(combo, "Custom", each [A]=null)
in
    #"Added Custom"

我们将不胜感激有关如何处理此问题的说明和建议。

编辑 除了上述之外，执行Replace 也只会替换第 3 行中的 null，而不是第 5 行中的 null。似乎有一些不同之处这两个空值。

注意：如果我展开表格，A列中的null现在将正确测试。

Answer 1

在 Microsoft 问答论坛上提出同样的问题，我指出 Power Query Evaluation model 和 Lazy Evaluation and Query Folding in Power BI/Power Query 上的这篇文章可能存在问题。

通过强制评估带有Table.Buffer 的表，现在两个空值的行为相同。

所以：

let
    Source1 = Table.FromRecords({
        [A="a"],
        [A="b"],
        [A=null],
        [A="c"]
    }),
    type1 = Table.TransformColumnTypes(Source1,{"A", type text}),
    Source2 = Table.FromRecords({
        [A="c"],
        [A="d"]
    }),
    type2 = Table.TransformColumnTypes(Source2,{"A", type text}),

//Table.Buffer forces evaluation
    combo = Table.Buffer(Table.NestedJoin(type1,"A",type2,"A","joined",JoinKind.FullOuter)),

//IsItNull now works
    IsItNull = Table.AddColumn(combo, "[A] = null", each [A] = null)
  in
    IsItNull

try ... otherwise 似乎也会强制进行评估。因此，除了 Table.Buffer，以下也可以：

    ...
    combo = Table.NestedJoin(type1,"A",type2,"A","joined",JoinKind.FullOuter),
//try ... otherwise seems to force Evaluation
    IsItNull = Table.AddColumn(combo, "[A] = null", each try [A] = null otherwise null)

Answer 2

非常有趣的案例。实际上，在大多数可能的实现中，last null 的行为是违反直觉的。如果您希望对两种空值都获得相同的行为，请尝试以下方法：

= Table.AddColumn(combo, "test", each [A] ?? 10)

很有意思，类似的代码不起作用：

= Table.AddColumn(combo, "test", each if [A] = null then 10 else [A])

此外，如果我们想通过使用第一个语法来改进之前的代码，我们仍然会得到意想不到的结果（最后一个 null 是 10 而不是 20）：

= Table.AddColumn(combo, "test", each if [A] = null then 10 else [A] ?? 20)

Сurious，应用 ?? 运算符也解决了初始列的问题。现在 A 列中有常规的空值：

= Table.AddColumn(add, "test2", each [A] = null)

所以，如果我们不需要任何计算，只想修复无效的空值，我们可以使用这样的代码：

= Table.TransformColumns(combo, {"A", each _ ?? _})

列无关紧要，对于 joined 列，结果是相同的：

transform = Table.TransformColumns(combo, {"joined", each _ ?? _}),
add = Table.AddColumn(transform, "test", each [A] = null)