DMF/DIXF AX 2012 R3 自定义生成方法

Question

我正在使用 Data Import Export Framework (DIXF) 解决文件交换（导出）问题，我想将生成方法添加到 Find LineAmount Purchline 与来自 PurchLine 表的接收行 VendPackingSlipTrans 关联。我创建了以下脚本，但我需要帮助：

[DMFTargetTransformationAttribute(true),DMFTargetTransformationDescAttribute("Function that generate LineAmount"),
 DMFTargetTransformationSequenceAttribute(11),
 DMFTargetTransFieldListAttribute([fieldStr(DMFVendPackingSlipTransEntity,LineAmount)])
]
public container GenerateLineAmount(boolean _stagingToTarget = true)
{

    container                  res;
    PurchLine                  purchLine;
    VendPackingSlipTrans       vendPackingSlipTrans;

    if (_stagingToTarget)
    {
        select firstOnly purchLine
            where purchLine.LineAmount                  == entity.LineAmount &&
                  vendPackingSlipTrans.OrigPurchid      == purchLine.PurchId &&
                  vendPackingSlipTrans.PurchaseLineLineNumber == purchLine.LineNumber;

        if ( ! purchLine )
        {
            entity.LineAmount = purchLine.LineAmount ;
            entity.insert();
        }
    }
    res = [entity.LineAmount];
    return res;
}

我必须使用 DMF 将数据从 ax 导出到文件，因此我在 VendPackingSlipTrans 中存在一些字段，因此在暂存表中添加了此字段，但其他字段存在于其他表中，例如 LineAmount。我不知道如何添加临时表中的其他字段。为此，我在 myEnityclass 中创建了生成方法来关联源表中的字段。到临时表

Answer 1

因此，您似乎希望使用数据导入/导出框架 (DIXF) 的自定义实体从 PurchLine 记录中导出带有附加信息的 VendPackingSlipTrans 记录。如果这是正确的，那么您的实现中存在几个问题：

1. if (_stagingToTarget)分支中的逻辑：由于框架既可以用于导入也可以用于导出，所以使用_stagingToTarget来区分两者。如果 _stagingToTarget 是 true，则数据将从临时表导入到 Dynamics AX 目标表。所以你需要把逻辑放在else 分支中。
2. PurchLine 记录的选择：当前实现永远不会选择PurchLine 记录，因为未实例化的VendPackingSlipTrans 表变量的值被用作选择语句中的条件。选择的标准也是错误的，请查看VendPackingSlipTrans 表的方法purchLine 以了解如何获取VendPackingSlipTrans 记录的PurchLine 记录并使用target 变量实例化VendPackingSlipTrans 表多变的。
3. 检查if (! purchLine)：这个检查意味着如果没有PurchLine记录可以用前面的select语句找到，这个空记录的LineAmount将被用于暂存记录。这是错误的，您想使用已找到记录的LineAmount。
4. entity.insert()：我在cmets中提到，实体记录不应该插入到generate方法中；框架将负责插入

这些问题的可能解决方法如下所示：

[
    DMFTargetTransformationAttribute(true),
    DMFTargetTransformationDescAttribute('function that determines LineAmount for export'),
    DMFTargetTransformationSequenceAttribute(11),
    DMFTargetTransFieldListAttribute([fieldStr(DMFVendPackingSlipTransEntity, LineAmount)])
]
public container GenerateLineAmount(boolean _stagingToTarget = true)
{
    container                  res;
    PurchLine                  purchLine;
    VendPackingSlipTrans       vendPackingSlipTrans;

    if (_stagingToTarget)
    {
        // this will be executed during import
        res = [0.0];
    }
    else
    {
        // this will be executed during export
        // the target variable contains the VendPackingSlipTrans that is exported
        vendPackingSlipTrans = target;
        purchLine = vendPackingSlipTrans.purchLine();
        if (purchLine)
        {
            res = [purchLine.LineAmount];
        }
    }
    return res;
}