具有多个 OR/AND 条件的 SUMIFS（使用单元格引用）

Question

      A             B              C            D               E            F          G        E
1  Products     Suppliers        Value     Criteria 1:     Product_C      Result:      600
2  Product_A    Supplier_01      500       Criteria 2:     Supplier_01      
3  Product_B    Supplier_01      600       Criteria 3:     Supplier_03  
4  Product_B    Supplier_02      300                
5  Product_C    Supplier_01      200                
6  Product_C    Supplier_01      400                
7  Product_C    Supplier_03      800    
8
9

在表格中，您可以找到不同的 Products (Column A) 和 Suppliers (Column B) 列表。

在Cell G1中，如果满足以下条件，我想获取Column C中的值的sum：

产品 = Product_C AND
供应商 = Supplier_01 或 Supplier_03

这些条件在Cells E1:E3 中输入为Criteria 1-3。

为了实现这一点，我尝试使用这些问题 (Q1,Q2) 的解决方案，这给了我正确的结果：

G1 =SUM(SUMIFS($C:$C,$A:$A,$E$1,$B:$B,{"Supplier_01","Supplier_02"}))

---

但是，我对这个解决方案的问题是我需要手动输入OR-criterias 作为{"Supplier_01","Supplier_02"}。
如何更改我的公式，以便我可以参考 Cells E2:E3 中的值，如果用户更改这些值，结果会自动调整？

Answer 1

一种可能性：

=SUMPRODUCT((A2:A7=E1)*((B2:B7=E2)+(B2:B7=E3))*C2:C7)

以相同的方式为 A 列和 B 列扩展标准将很容易。

Answer 2

我要说你需要转置 E2:E3。我认为这通常是正确的，但在这种特殊情况下，只有一个标准适用于 A 列，您不需要：

=SUM(SUMIFS($C:$C,$A:$A,$E$1,$B:$B,$E$2:$E$3))

如果输入为数组公式，则有效。

如果您对 A 和 B 有多个条件，则确实需要转置一组条件：

=SUM(SUMIFS($C:$C,$A:$A,$E$1:$E$2,$B:$B,TRANSPOSE($E$3:$E$4)))

Answer 3

试试这个

=SUM(SUMIFS($C:$C,$A:$A,$E$1,$B:$B,E2:E3))

或

=SUM(IF(($A$2:$A$7=E1)*(($B$2:$B$7=E2)+($B$2:$B$7=E3)),$C$2:$C$7,0))