Excel：iferror 应该返回什么以避免#value！错误

Question

这可能很简单，但似乎我无法找到解决方案。无论如何，谷歌搜索没有运气（可能是错误的关键字）：

我需要计算所有找到的 vlookup 结果的平均值并忽略所有未找到的值。

我目前拥有的：

 = AVERAGE(
    IFERROR(VLOOKUP(A4,table01,2,0),""),
    IFERROR(VLOOKUP(A4,table02,2,0),""),
    IFERROR(VLOOKUP(A4,table03,2,0),""),
    IFERROR(VLOOKUP(A4,table04,2,0),""),
    IFERROR(VLOOKUP(A4,table05,2,0),""),
    IFERROR(VLOOKUP(A4,table06,2,0),""),
    IFERROR(VLOOKUP(A4,table07,2,0),""),
    IFERROR(VLOOKUP(A4,table08,2,0),""),
    IFERROR(VLOOKUP(A4,table09,2,0),""),
    IFERROR(VLOOKUP(A4,table10,2,0),""),
    IFERROR(VLOOKUP(A4,table11,2,0),""),
    IFERROR(VLOOKUP(A4,table12,2,0),"")
)

每一行都可以正常工作，但如果在多个表之一中找不到该值，则平均值将始终导致 #Value! 错误。如果没有找到 IFERROR 返回我“”。

为了使平均值起作用，我应该在 IFERROR 字段中输入什么而不是 ""？

• 将其替换为 0 会计算值并降低平均值，这不应该

谢谢你

Answer 1

我对罗恩的建议很感兴趣。
正如您在他的回答中所评论的那样，您需要制作 120 个帮助列才能做到这一点。
在我看来，您只需要一个 12 x 10 的辅助单元矩阵。
而且您只需要一个公式。

考虑一下这个简单的示例数据：

您正在如图所示的所有 3 个表中查找 Data1 的平均值（Value1 和 Value2）。
所以这就像查看 3 个表，每个表有 2 列。
根据 Ron 的建议，它将需要 6 个辅助列和 6 个不同的公式。

这是我的建议。
让我们创建一个辅助矩阵，如下所示：

我们使用下面的公式来创建矩阵：

=IFERROR(VLOOKUP(A2,INDIRECT({"Table1","Table2","Table3"}),{2;3},0),"")

这是一个数组公式。

首先选择D7:F8（您的矩阵），然后单击公式栏并输入公式。
使用 Ctrl+Shift+Enter 将其输入为 Array Formula。

检查矩阵，它返回我们需要的所有值：

对于未找到的值，它会返回 ""。
辅助矩阵完成后，您可以简单地输入：

=AVERAGE(D7:F8) 或
=AVERAGE(matrix)（如果您想为您的矩阵创建一个命名范围）

在 B2 中基于我们的示例数据布局。结果将是 3。
HTH。哪个更容易设置完全取决于您。

Answer 2

我无法提供让Average 或其表亲忽略此类列表中的错误的方法（如果它是一系列值，包括错误，那么可以做到...）

作为替代方案，使用 `Sum(...) / Count(...) 方法（仅显示前两个表格）

=SUM(
 IFERROR(VLOOKUP(A4,Table1,2,0),),
 IFERROR(VLOOKUP(A4,Table2,2,0),)
) / SUM(
 ISNUMBER(VLOOKUP(A4,Table1,2,0)),
 ISNUMBER(VLOOKUP(A4,Table2,2,0))
)

Answer 3

不要将所有这些 IFERROR(VLOOKUP... 函数用作 AVERAGE 函数中的参数，而是将每个函数放入单独的单元格中，然后在 AVERAGE 函数中引用范围。

例如：

=AVERAGE(F1:F10)

在哪里

F1:  IFERROR(VLOOKUP(A4,table01,2,0),"")
F2:  IFERROR(VLOOKUP(A4,table02,2,0),"")

等等。

来自 AVERAGE 函数的 HELP：

如果范围或单元格引用参数包含文本、逻辑值、 或空单元格，这些值将被忽略；然而，细胞与 包括零值。

参数是错误值或文本 不能转换成数字会导致错误。