如何在替换文本中正确使用 sed 中捕获的组？

Question

只是没有足够的 sed 用户能够弄清楚这一点。我正在尝试将下划线转换为 lodash，这需要将许多调用从 _(obj).method() 更改为 _.method(obj)。我一直在尝试使用 sed 来做到这一点：

sed "s/_(\(.*\)).\(.*\)(/_.\2(\1, /"

这种模式实际上适用于一行中的单个实例。例如

echo "_(foo).bar('blah')" | sed "s/_(\(.*\)).\(.*\)(/_.\2(\1, /"

实际上输出了预期的结果：_.bar(foo, 'blah')。问题是当一行出现多次时。例如

echo "_(foo).bar('baz') yep _(baz).quux('blah')" | sed "s/_(\(.*\)).\(.*\)(/_.\2(\1, /"

输出_.quux(foo).bar('baz') yep _(baz, 'blah') 和

echo "_(foo).bar('baz') yep _(baz).quux('blah')" | sed "s/_(\([^(]*\)).\(.*\)(/_.\2(\1, /"

输出_.bar('baz') yep _(baz).quux(foo, 'blah')。

所以，我显然只是不明白如何在我的替换文本中使用捕获组。顺便说一句，在末尾添加 /g 并不能解决此问题。

Answer 1

这就是你要找的吗？

sed -r 's/_\(([^)]*)\)\.([^(]*\()([^)]*\))/_.\2\1,\3/g'

用你的例子：

kent$  echo "_(foo).bar('baz') yep _(baz).quux('blah')" | sed -r 's/_\(([^)]*)\)\.([^(]*\()([^)]*\))/_.\2\1,\3/g'
_.bar(foo,'baz') yep _.quux(baz,'blah')

更新，您的代码上的 cmets：

我查看了您的代码，并进行了一些修改，现在它可以在这里工作了。

Yours : sed "s/_(\([^(]*\)).\(.*\)(/_.\2(\1, /"
Mine  : sed "s/_(\([^)]*\))\.\([^(]*\)(/_.\2(\1, /g"

• 记住，sed 总是贪婪匹配，所以，你必须使用[^something]。检查我改变的地方。
• 当您希望点 (.) 与文字 . 匹配时，应将其转义。
• 需要g 标志