如何在一个块中检查多个变量的类型？

Question

如何在一个if 语句块中检查多个变量的类型，而不使用多个if 语句？示例：

If var1 is not integer
{
    MsgBox, 0, Error, var1 is not integer
    Return
}
If var2 is not integer
{
    MsgBox, 0, Error, var2 is not integer
    Return
}

我想做的是检查单个布尔表达式中的类型。

我试过了，但它不起作用。

if ((var1 is not integer) or (var2 is not integer))
{
    MsgBox, 0, Error, variables are not integers
    Return
}

Answer 1

AHK 中的特殊 If 命令，如 If var [not] between、If var [not] in/contains MatchList、If var is [not] type、IfWin... 不是实际的布尔表达式，因此您不能链接 使用布尔运算符。
但是，这些条件语句可以包装在一个函数中。此外，If var is [not] type 可以使用 RegEx 重建：

方案一：包装函数

isInteger(arg) {
    if arg is integer
        return true
    else
        return false
}

if(isInteger(123) && isInteger(456)) {
    MsgBox, yay!
}

解决方案 2：正则表达式

if(RegExMatch(123, "^\d+$") && RegExMatch(456, "^\d+$")) {
    msgbox, hooray!
}

一些测试

如果您有兴趣，请查看数组值，复制脚本并运行它。你可能会发现一些令人惊讶的结果。我们的包装函数和RegExMatch 提供相同的背靠背结果。

arr := [123, 456, 123.456, "789", "not_an_integer!", true, false]
msg := ""
Loop % arr.MaxIndex()
{
    msg .= arr[A_Index]
    msg .= ":`tisInteger(): " isInteger(arr[A_Index])
    msg .= " RegExMatch(): " RegExMatch(arr[A_Index], "^\d+$")
    msg .= "`n"
}
msgbox  % msg


isInteger(arg) {
    if arg is integer
        return true
    else
        return false
}