在 27 页文档上运行宏时 Word 内存不足

Question

这篇文章被交叉发布在Microsoft Answers forum。

我下面的宏用于保护有问题的 Word 文档。当它在较小的文档（4-10 页）上运行时，它工作得很好，但是我们有一个更大的 27 页文档（6000 字），它似乎占用了所有的内存！我运行它，结果让我僵住了。

这里是 OneDrive 可重现示例的链接：https://1drv.ms/w/s!AgPO3BotYSt7iHvafHts2HyF2OjB?e=HSOI57

不确定通过 OneDrive 访问时格式是否成立，但单击复选框时会显示 X。

“您将如何满足推荐的描述”后面是一个文本字段，以便用户输入文本。同样处理“负责任的团队”和“为什么你不同意：”

宏运行后，整个文档应该被锁定，除了红色的文本以及上述格式。

是否可以调整宏以节省一些内存，使其在用于较大文件时运行？

这是宏：

Sub Lock_Teammate_DraftReports_mp()

Selection.HomeKey wdStory

Selection.Find.ClearFormatting

Selection.Find.Font.ColorIndex = wdRed

With Selection.Find

    Do While .Execute(FindText:="", Forward:=True, MatchWildcards:=False, Wrap:=wdFindStop) = True

        Selection.Editors.Add wdEditorEveryone

        Selection.Collapse wdCollapseEnd

    Loop

End With

ActiveDocument.Protect Password:="example123", NoReset:=False, Type:=wdAllowOnlyReading, 
UseIRM:=False, EnforceStyleLock:=False

End Sub

Answer 1

您的问题很可能与您的代码正在执行的所有选择有关，这既低效又容易导致大量滚动和屏幕闪烁。试试：

Sub Lock_Teammate_DraftReports_mp()
Application.ScreenUpdating = False
Dim i As Long
With ActiveDocument
  With .Range
    With .Find
      .ClearFormatting
      .Font.ColorIndex = wdRed
      .Text = ""
      .Forward = True
      .Wrap = wdFindStop
      .MatchWildcards = False
    End With
    Do While .Find.Execute = True
      i = i + 1
      If .Information(wdWithInTable) = True Then
        If .Rows(1).Range.Font.ColorIndex = wdRed Then .End = .Rows(1).Range.End
        If .End = .Cells(1).Range.End - 1 Then .End = .Cells(1).Range.End
        If .Information(wdAtEndOfRowMarker) = True Then .End = .End + 1
      End If
      .Editors.Add wdEditorEveryone
      If .End = ActiveDocument.Range.End Then Exit Do
      .Collapse wdCollapseEnd
      If i Mod 100 = 0 Then DoEvents
    Loop
  End With
  .Protect Password:="example123", NoReset:=False, Type:=wdAllowOnlyReading, UseIRM:=False, EnforceStyleLock:=False
End With
Application.ScreenUpdating = True
End Sub