AppleScript：如何在没有隐藏文件的文件夹中获取文件？

Question

其实我有两个问题。

当我尝试获取文件夹中的文件时，如何排除 .DS_STORE、Icon 等隐藏文件？ 我试过“without invisibles”，但它似乎不起作用。

如果已经存在，如何将我的 var the_new_folder 设置为现有文件夹？

感谢您的回答。

我的代码：

--
-- Get all files in a selected folder
-- For each file, create a folder with the same name and put the file in
--

tell application "Finder"
    set the_path to choose folder with prompt "Choose your folder..."
    my file_to_folder(the_path)
end tell

on file_to_folder(the_folder)
    tell application "Finder"

        -- HELP NEEDED HERE
        -- HOW TO EXCLUDE HIDDEN FILES (Like Icon, .DS_STORE, etc)
        set the_files to files of the_folder

        repeat with the_file in the_files

            -- Exclude folder in selection
            if kind of the_file is not "Folder" then
                set the_path to container of the_file
                set the_file_ext to name extension of the_file

                -- Remove extension of the file name
                set the_file_name to name of the_file as string
                set the_file_name to text 1 thru ((offset of the_file_ext in (the_file_name)) - 2) of the_file_name

                -- Make the new folder with the file name
                try
                    set the_new_folder to make new folder at the_path with properties {name:the_file_name}
                on error
                    -- HELP NEEDED HERE
                    -- HOW TO SET the_new_folder AS THE EXISTING FOLDER
                end try

                -- Move the file in the new folder
                move the_file to the_new_folder

            end if
        end repeat

    end tell
end file_to_folder

tell application "Finder"
    (display dialog ("It's done!") buttons {"Perfect!"})
end tell

Answer 1

使用System Events 上下文而不是Finder：

• 绕过AppleShowAllFiles首选项的问题^[1]

• 总体上要快得多。

在System Events 上下文中使用file / folder 对象的visible 属性允许您可预测地 确定所有 项，包括隐藏的项（默认情况下），或者只有 可见 的（带有whose visible is true）：

# Sample input path.
set the_path to POSIX path of (path to home folder)

tell application "System Events"

    set allVisibleFiles to files of folder the_path whose visible is true

end tell

只需省略 whose visible is true 即可包含隐藏文件。

---

引用预先存在的文件夹或按需创建它的代码与Finder 上下文中的代码基本相同：

# Sample input path.
set the_path to POSIX path of (path to home folder)

# Sample subfolder name
set the_subfolder_name to "subfolder"

tell application "System Events"

    if folder (the_path & the_subfolder_name) exists then
        set subfolder to folder (the_path & the_subfolder_name)
    else
        set subfolder to make new folder at folder the_path ¬
          with properties {name: the_subfolder_name}
    end if

end tell

---

^[1]为了可预测地排除隐藏项目，基于Finder的解决方案不仅麻烦而且副作用很大：

• 您需要确定AppleShowAllFiles 首选项(defaults read com.apple.Finder AppleShowAllFiles) 的当前状态，
• 然后将其关闭。
  • 然后 kill Finder 以使更改生效（它会自动重新启动） - 这会在视觉上造成破坏
• 然后，在您的代码运行后，将其恢复为之前的值。
  • 然后再次杀死Finder，让恢复的值再次生效。

Answer 2

我相信你的第一个问题不是问题。你的代码对我来说很好。

至于第二个问题，最简单的方法是使用the_path的文本表示，直接新建文件夹，看看是否已经存在：

set the_path_Text to (the_path as text)
set try_Path to the_path_Text & the_file_name
if (folder try_Path) exists then
    set the_new_folder to (folder try_Path)
else
    set the_new_folder to make new folder at the_path with properties {name:the_file_name}
end if

如果您对第一个代码部分确实有困难，请发布一个包含更多详细信息的新问题，例如脚本的 结果 部分的副本。

Answer 3

谢谢大家！ @mklement0 @craig-smith

在您的帮助下，您将在下方找到更正后的代码！

如果我分享此代码，您想被引用以表示感谢吗？

--
-- Get all files in a selected folder
-- For each file, create a folder with the same name and put the file in
--


-- Get user folder
set the_path to choose folder with prompt "Choose your folder..."
my file_to_folder(the_path)


on file_to_folder(the_folder)

    tell application "System Events"

        -- Get all files without hidden
        set the_files to files of the_folder whose visible is true

        repeat with the_file in the_files

            -- Remove extension of the file name
            set the_file_ext to name extension of the_file
            set the_file_name to name of the_file as string
            set the_file_name to text 1 thru ((offset of the_file_ext in (the_file_name)) - 2) of the_file_name

            -- Make a new folder or get the existing
            set the_path to POSIX path of the_folder
            if folder (the_path & the_file_name) exists then
                set the_new_folder to folder (the_path & the_file_name)
            else
                set the_new_folder to make new folder at folder the_path with properties {name:the_file_name}
            end if

            -- Move the file to the new folder
            move the_file to the_new_folder

        end repeat

    end tell
end file_to_folder


-- Ending dialog
display dialog ("It's done!") buttons {"Perfect!"}