Applescript 进度条不起作用

Question

我有一个正常工作的进度条码，但是当我将它与一些任务混合使用时，比如在这里复制文件，它给了我错误并且不会增加，它在第一次复制后停止，知道问题出在哪里吗？

代码如下：

tell application "Finder"
    set selected_items to selection
    set fileCount to length of selected_items
end tell

set progress total steps to fileCount
set progress completed steps to 0
set progress description to "Processing Images..."
set progress additional description to "Preparing to process."
set a to 1

tell application "Finder"
    set theFolder to POSIX file "/Users/graphics/Desktop/1"
    repeat with x in selected_items
        set progress additional description to "Processing image " & a & " of " & fileCount
        duplicate x to theFolder
        set progress completed steps to a + 1
        set a to a + 1
    end repeat
end tell

Answer 1

这是脚本，请阅读下面的注释：

tell application "Finder"
    set selected_items to selection
    set fileCount to count of selected_items
end tell

set progress total steps to fileCount
set progress completed steps to 0
set progress description to "Processing Images..."
set progress additional description to "Preparing to process."
set a to 1

repeat with x in selected_items
    set progress additional description to "Processing image " & a & " of " & fileCount
    tell application "Finder"
        set theFolder to (path to desktop folder as string) & "1:"
        duplicate x to theFolder with replacing
    end tell
    tell me to set progress completed steps to a + 1
    set a to a + 1
end repeat

我将set progress... 处理程序移出tell application "Finder"-Block，因为应用程序“Finder”不知道进度条，并更正了目标文件夹以匹配任何桌面文件夹。现在完美运行，如果

• 脚本保存为小程序
• 小程序通过 Dock 启动

这是因为

• 在脚本编辑器中运行时，脚本编辑器无法处理更新进度条的不同线程

• 如果您通过在 Finder 中双击来启动 Applet，Applet 本身就会成为选择，因为您单击它！从扩展坞启动它可以解决这个问题！

玩得开心，迈克尔/汉堡