在子目录中打开固定长度文件名的批处理循环

Question

我在编写代码方面已经走了这么远（在你们的帮助下here），但它并没有做它应该做的事情..

批处理的目标是打开所有 K_E*.dwg 文件并在这些文件上执行脚本。 K_E*.dwg 文件的长度应为 9。例如 K_E123456.dwg。

到目前为止，这段代码打开了一个dos窗口并再次关闭它.. 我的文件夹结构是这样的：

C:\Users\b00m49\Desktop\LSPTEST\0031\00\K_E000031.dwg

C:\Users\b00m49\Desktop\LSPTEST\0031\01\K_E010031.dwg

C:\Users\b00m49\Desktop\LSPTEST\0032\00\K_E000032.dwg

C:\Users\b00m49\Desktop\LSPTEST\0033\00\K_E000033.dwg ...

运行此代码的任何帮助都会很棒..

我对批处理非常陌生，所以对步骤的解释可能很方便，并且可能让我解决小问题。

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
SET "sourcedir=C:\Users\b00m49\Desktop\LSPTEST"
for /r "%sourcedir%" %%a in (K_E*.dwg) do (
 FOR /f "tokens=1,9delims=\" %%m IN ("%%a") DO (
  REM %%n contain dirname or filename or empty
  REM %%n is only empty for 0, 1 or 2 levels down.
  IF "%%n"=="" (
   SET "name=%%~na"
   IF "!name:~9!"=="" IF "!name:~8!" neq "" (
    REM the name is not longer than 9 characters, but IS longer than 8
     ECHO(start /wait "C:\Program Files\Autodesk\Autocad 2013\acad.exe" "%%a" /b "C:\Users\b00m49\Desktop\LSPTEST\expSQM.scr")
   )
  )
 )
)
GOTO :EOF

Answer 1

您可以改用这种方法，它可以更好地识别所需的文件名：

@echo off
setlocal

set "sourcedir=C:\Users\b00m49\Desktop\LSPTEST"
cd "%sourcedir%"
for /F "delims=" %%a in ('dir /S /B K_E*.dwg ^| findstr "\\K_E[0-9][0-9][0-9][0-9][0-9][0-9]\.dwg"') do (
   ECHO start /wait "" "C:\Program Files\Autodesk\Autocad 2013\acad.exe" "%%a" /b "C:\Users\b00m49\Desktop\LSPTEST\expSQM.scr"
)

for /r "%sourcedir%" %%a 命令替换为cd "%sourcedir%" 和后面的dir /S 命令；此方法处理相同的文件：源目录内任何级别的所有文件。文件列表通过| 管道传递到findstr filter 命令，该命令允许精确地传递那些具有“\K_E”+6 位数字+“.dwg”的名称。有关详细信息，请键入 findstr /?。输出由for /F "delims=" %%a 命令获取。

PS - 为什么你使用start /wait 命令？其实际效果与单独执行acad.exe 命令相同...

Answer 2

我是这个网站的新手，没有注意到有人将他的评论编辑成有效的东西..

我不完全明白怎么做，但这里是代码。

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
SET "sourcedir=U:\Users\b00m49\Desktop\LSPTEST"
for /r "%sourcedir%" %%a in (K_E*.dwg) do (
 FOR /f "tokens=1,9delims=\" %%m IN ("%%a") DO (
  REM %%n contain dirname or filename or empty
  REM %%n is only empty for 0, 1 or 2 levels down.
  IF "%%n"=="" (
   SET "name=%%~na"
   IF "!name:~9!"=="" IF "!name:~8!" neq "" (
    REM the name is not longer than 9 characters, but IS longer than 8
     ECHO(start /wait "" "C:\Program Files\Autodesk\Autocad 2013\acad.exe" "%%a" /b "C:\Users\b00m49\Desktop\LSPTEST\expSQM.scr")
   )
  )
 )
)
pause
GOTO :EOF

Answer 3

改变

 ECHO(start /wait "C:\Program Files\Autodesk\Autocad 2013\acad.exe" "%%a" /b "C:\Users\b00m49\Desktop\LSPTEST\expSQM.scr")

到

 start /wait "" "C:\Program Files\Autodesk\Autocad 2013\acad.exe" "%%a" /b "C:\Users\b00m49\Desktop\LSPTEST\expSQM.scr")

或到

 start "" "C:\Program Files\Autodesk\Autocad 2013\acad.exe" "%%a" /b "C:\Users\b00m49\Desktop\LSPTEST\expSQM.scr")

应该并行运行所有转换。