VBA CountIf 问题

Question

vba 中的 countif 函数有问题（最后两行代码）。它必须计算一定范围内的某些值，但是它绝对将每个值都计为 mp3 而没有任何值计为 mp4。

最奇怪的是，当我将程序复制到一个新的单独模块中时，没有传递变量，一切正常，返回正确的值。这里有什么问题？谢谢

Private Sub FindValue(ByVal fileno As String, ByVal deadline As String)

Dim i As Integer
Dim xWs As Worksheet
Dim rng As Range
Dim olApp As Object
Dim olMail As Object
Dim var As Integer
Dim user As String
Dim uplDate As String
Const olMailItem = 0
Dim lastrow As Long
Dim mp3 As Long
Dim mp4 As Long

Sheets("Add_User_ID").Select
var = Sheets("Add_User_ID").Range(("A2"), Sheets("Add_User_ID").Range("A2").End(xlDown)).Rows.Count
If fileno = "" Then
fileno = InputBox("File number")
End If
If deadline = "" Then
deadline = InputBox("Deadline, any format(e.g. 27th of August EOD)")
End If
uplDate = Format(Date, "YYYYMMDD")

For i = 2 To var + 1
user = Sheets("Add_User_ID").Cells(i, "A").Value
Sheets("allocation").Select
With ActiveSheet
    .AutoFilterMode = False
    .Range("A:I").AutoFilter
    .Range("A:A").AutoFilter field:=1, Criteria1:=user
End With

Sheets("allocation").Range("A1").Select
Set rng = ActiveCell.CurrentRegion
Application.Workbooks.Add
Set xWs = Application.ActiveSheet
rng.Copy Destination:=xWs.Range("A1")
lastrow = xWs.Cells(Rows.Count, 2).End(xlUp).Row - 1
mp3 = WorksheetFunction.CountIf(Range(Cells(2, 4), Cells((lastrow + 1), 4)), 3)
mp4 = WorksheetFunction.CountIf(Range(Cells(2, 4), Cells((lastrow + 1), 4)), 4)

Answer 1

把代码结尾改成这样：

with xWs
    mp3 = WorksheetFunction.CountIf(.Range(.Cells(2, 4), .Cells((lastrow + 1), 4)), 3)
    mp4 = WorksheetFunction.CountIf(.Range(.Cells(2, 4), .Cells((lastrow + 1), 4)), 4)
end with

没有 With 和 .，Cells 和 Range 指的是活动表。因此，最好自己参考。

然后，如果您愿意，请像这样重构您的代码：

• 将"" 更改为vbNullString Is there any difference between vbNullString and ""?
• 在任何地方将Integer 更改为Long Why Use Integer Instead of Long?
• 确保您始终参考您正在使用的工作表并避免使用ActiveSheet 和Select。 How to avoid using Select in Excel VBA
• 考虑自动缩进的解决方案 - RubberDuck 或 SmartIndenter