如何根据列表的后半部分简洁匹配列表，并相应地绑定它的前半部分？

Question

假设我有一个函数f :: String -> String 并且想要匹配表单的参数

_ ++ "bar"

其中_ 是我想返回的未指定字符串。换句话说，我想匹配foobar 和bazbar 之类的参数，并分别返回foo 和baz。

使用ViewPatterns 可以如下实现：

{-# LANGUAGE ViewPatterns #-}

f :: String -> String
f x@(reverse . take 3 $ reverse -> "bar") = take (n-3) x
    where n = length x

...但这远非理想。主要是因为如果我决定要组合两个或多个这样的模式，事情会很快变得棘手。

理想情况下，我希望能够写出这样的东西：

f (x:"bar") = x

但不幸的是，这不是有效的 Haskell。

ViewPatterns 或其他扩展中是否有适当的解决方案？

Answer 1

在内置 String 上，这是一个非常糟糕的主意，因为您的模式匹配结果非常昂贵。在其他字符串类型上，例如 Text 或 ByteString，您可以使用模式保护：

{-# LANGUAGE OverloadedStrings #-}

import qualified Data.Text as T

f :: Text -> Text
f x | Just x' <- T.stripSuffix "bar" x = ...

或者ViewPatterns（我不太喜欢）：

{-# LANGUAGE OverloadedStrings, ViewPatterns #-}

import qualified Data.Text as T

f :: Text -> Text
f (T.stripSuffix "bar" -> Just x') = ...

Answer 2

stripSuffix :: (Eq a) => [a] -> [a] -> Maybe [a]
stripSuffix needle = go <*> drop (length needle)
  where
    go xs [] = if xs == needle then Just [] else Nothing
    go (x:xs) (_:ys) = (x:) <$> go xs ys

f (stripSuffix "bar" -> Just pref) = pref

我没有对其进行过多测试，但这是一个简单的解决方案，不会引入额外的正则表达式/解析器机制。

Answer 3

不要使用模式匹配。模式匹配通常很便宜并且匹配输入数据的结构。这是一个非常昂贵的模式，编写起来好像计算起来非常便宜。如果你想这样做，把它写成一个保护子句，在那里你可以清楚地说明发生了什么。

Answer 4

这几乎可以使用 TemplateHaskell - 更有经验的人可以改进这个答案。

import Language.Haskell.TH
import Language.Haskell.TH.Syntax

(+++) :: Q Pat -> String -> Q Pat
x +++ y = [p| ((\string -> splitAt (length string - length y) string) -> (x, $literal_pattern)) |]
  where literal_pattern = returnQ (LitP (StringL y))

这可用于模式位置，您可以使用 TemplateHaskell 的 quasiquoting 将模式作为第一个参数传递：

f $([p|x|] +++ "bar") = x

相当烦人的是，我找不到比这更简洁的解释来说明如何将模式传递给 TemplateHaskell 拼接。