【问题标题】:How could I make a list in Haskell by prime index?我怎样才能在 Haskell 中通过素数索引列出一个列表?
【发布时间】:2019-12-16 04:19:34
【问题描述】:

我如何制作一个列表来获取每个具有素索引号的数字/字母?

primeIndex :: [a] -> [a]
primeIndex [1..20] == [2, 3, 5, 7, 11, 13, 17, 19]
primeIndex "primesarefun" == "rieau"

【问题讨论】:

  • 这真的是两个问题合二为一。第一个是如何在 Haskell 中找到素数,第二个是如何通过元素的索引过滤列表(与通常的按值过滤的情况相反)。 @WillemVanOnsem 提供了一个链接,这将有助于第一个。你坚持哪一块?
  • 为什么需要主要索引处的项目..?

标签: haskell


【解决方案1】:

一种可能的策略:

按照@Joseph Sible-Reinstate Monica 上面提到的一般方法,问题可以这样解决:

  1. 获取所有素数的列表,例如primes
  2. 使用第一个列表创建一个辅助布尔值列表,其中 True 元素仅位于主要索引处
  3. 将第二个列表与经典列表函数(map、filter、zip)一起使用来解决问题

关于第一部分,relevant page of the Haskell Wiki 中有许多可用的算法。我们只能选择其中之一。

import  Data.List.Ordered

_Y   :: (t -> t) -> t
_Y g = g (_Y g)    

joinL :: (Ord a, Eq a) => [[a]] -> [a]
joinL ((x:xs):t) = x : union xs (joinL t)
joinL ([]:t)     = joinL t
joinL  []        = []

primesLME :: [Integer]
primesLME = 2 : _Y ((3:) . minus [5,7..] . joinL . map (\p-> [p*p, p*p+2*p..]))

primes = primesLME

LME 代表线性合并。

关于第二部分,可以从SO_q59092535 获取将primes 转换为所需布尔值列表(例如primeMask)的函数。

-- boolean list from index list (with unfoldr):
booleansFromIndices :: [Integer] -> [Bool]
booleansFromIndices indices =
    let  sfn (pos,ind) =  Just $  -- stepping function for unfoldr
             if (null ind)
               then ( False, (pos+1, []) )
               else ( pos==head ind,
                      (pos+1, if (pos==head ind)  then  tail ind  else  ind))
    in   unfoldr  sfn  (0,indices)

primeMask :: [Bool]
primeMask = drop 1 $ booleansFromIndices primes  -- 1-based indexing

把它们放在一起(第三部分和最后一部分):

在ghci 会话中:

 λ> 
 λ> take 10 primes
[2,3,5,7,11,13,17,19,23,29]
 λ> 
 λ> 
 λ> take 15 primeMask
[False,True,True,False,True,False,True,False,False,False,True,False,True,False,False]
 λ> 
 λ> take 20 $ map  (\b -> if b then '1' else '0')  primeMask
"01101010001010001010"
 λ> 
 λ> str = "primesarefun"
 λ> 
 λ> zip primeMask str
[(False,'p'),(True,'r'),(True,'i'),(False,'m'),(True,'e'),(False,'s'),(True,'a'),(False,'r'),(False,'e'),(False,'f'),(True,'u'),(False,'n')]
 λ> 
 λ> filter fst $ zip primeMask str
[(True,'r'),(True,'i'),(True,'e'),(True,'a'),(True,'u')]
 λ> 
 λ> map snd $ filter fst $ zip primeMask str
"rieau"
 λ> 
 λ> primeIndex = \xs -> map snd $ filter fst $ zip primeMask xs
 λ> 
 λ> primeIndex [1..20]
[2,3,5,7,11,13,17,19]
 λ> 

【讨论】:

    猜你喜欢
    • 2021-08-03
    • 1970-01-01
    • 2023-01-02
    • 2012-11-22
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 2011-05-20
    相关资源
    最近更新 更多